在單片機開(kāi)發(fā)過(guò)程中.一些非線(xiàn)性的控制過(guò)程.最適合做一個(gè)表格來(lái).時(shí)時(shí)改變系統的參數.達到控制的目的.最常的如產(chǎn)生正弦的的程.就是建一個(gè)大的數組時(shí)時(shí)改變輸出的8位字節送給外部DA.由DA生成一個(gè)完整的正弦波.當然了.LED顯示也是一個(gè)例子.通過(guò)建一個(gè)數組來(lái)實(shí)現段碼的點(diǎn)亮點(diǎn)滅.下面就是一個(gè)LED表---digits[0]
#define SEG_a 0x01
#define SEG_b 0x02
#define SEG_c 0x04
#define SEG_d 0x08
#define SEG_e 0x10
#define SEG_f 0x20
#define SEG_g 0x40
#define SEG_dot 0x80
unsigned char digits[10] = {
(SEG_a|SEG_b|SEG_c|SEG_d|SEG_e|SEG_f), // 0
(SEG_b|SEG_c), // 1
(SEG_a|SEG_b|SEG_d|SEG_e|SEG_g), // 2
(SEG_a|SEG_b|SEG_c|SEG_d|SEG_g), // 3
(SEG_b|SEG_c|SEG_c|SEG_f|SEG_g), // 4
(SEG_a|SEG_c|SEG_d|SEG_f|SEG_g), // 5
(SEG_a|SEG_c|SEG_d|SEG_e|SEG_f|SEG_g), // 6
(SEG_a|SEG_b|SEG_c), // 7
(SEG_a|SEG_b|SEG_c|SEG_d|SEG_e|SEG_f|SEG_g), // 8
(SEG_a|SEG_b|SEG_c|SEG_d|SEG_f|SEG_g) // 9
};
C查表就太簡(jiǎn)單了temp2 = digits[ show_data[i] ];一句搞定,C中還有一個(gè)switch語(yǔ)句也是一個(gè)很好的用查表語(yǔ)句
C51匯編就相對麻煩一點(diǎn).不過(guò)MCS-51指令系統中有專(zhuān)用的查表指令：MOVC A,@A+DPTR和MOV A,@A+PC.
MOVC A,@A+DPTR指令，DPTR作為基址寄存器時(shí)，其值為16位而且可根據需要設計，故可用于在64KROM范圍內查表。編寫(xiě)查表程序時(shí)，首先把表的首址送入DPTR中，再將要查找的數據序號（或下表值）送入A中，然后就可以使用該指令進(jìn)行查表操作，并將結果送累加器A中。
MOVC A,@A+PC指令，PC作為基址寄存器時(shí)，其值由指令的位置確定，它只能設在查表指令操作碼下的256個(gè)字節范圍內。編寫(xiě)查表程序時(shí)，首先把查表數據的序號送入A中，再把從查表指令到表的首地址間的偏移量與A值相加，然后使用該指令進(jìn)行查表操作，并把結果送累加器A中。
下面是把內部RAM 30H-37H單元中的十六進(jìn)制數依次轉換為ASCII碼，并存入內部RAM 60H-6FH單元之中。用查表法編寫(xiě)程序。
分析：由于十六進(jìn)制數是從0～F，對應的ASCII碼為30H～46H，每一個(gè)單元存放的16進(jìn)制數，轉換為ASCII碼后分別存入2個(gè)單元，低位存低地址，高位存高地址。用ANL A ，#0FH 分別取高4位和低4位。 進(jìn)行查表轉換成相應的ASCII碼。
MOVC A , @A+DPTR 程序如下：
ORG 0000H
AJMP MAININITIAL
ORG 0050H
MAININITIAL: ;給30H-37H賦初值
MOV R0,#30H ;設置存數指針R0初值
MOV R1,#00H ;設置賦值變量個(gè)數計數寄存器R1(循環(huán)計數器)初值
MOV DPTR,#initialtab
NEXTINITIAL:
MOV A,R1
MOVC A,@A+DPTR ;查表數據送累加器A
MOV @R0,A
INC R0 ;指針增一
INC R1 ;循環(huán)計數器增一
CJNE R1,#8,NEXTINITIAL ;判給30H-3FH賦初值完否
MAIN:
MOV R0,#30H ;設置十六進(jìn)制數地址指針
MOV R1,#60H ;設置ASCII碼地址指針
MOV R7,#08H ;需拼裝的十六進(jìn)制數字節個(gè)數
MOV DPTR,#ACSIITAB
ABC:
MOV A,@R0 ;取十六進(jìn)制數
MOV B,A ;暫存
ANL A,#0F0H ;取十六進(jìn)制數的字節高4位
RR A ;取十六進(jìn)制數的字節高4位移到字節的低4位
RR A
RR A
RR A
MOVC A,@A+DPTR ;查表數據送累加器A
MOV @R1,A ;保存轉換結果
INC R1 ;轉換結果指針增一
MOV A,B
ANL A,#0FH ;取十六進(jìn)制數的字節低4位
MOVC A,@A+DPTR ;查表數據送累加器A
MOV @R1,A ;保存轉換結果
INC R1 ;轉換結果指針增一
INC R0 ;轉換數據指針增一
DJNZ R7,ABC ;繼續
SJMP $
initialtab: ;給30H-37H賦值用初值表
DB 23H,6DH,09H,7FH,8CH,1EH,4BH,5AH
ACSIITAB: ;0～F，對應的ASCII碼表
DB "012345678"
DB "9ABCDEF"
END
MOVC A,@A+PC程序如下：
ORG 0000H
AJMP MAININITIAL
ORG 0050H
MAININITIAL: ;給30H-37H賦初值
MOV R0,#30H ;設置存數指針R0初值
MOV R1,#00H ;設置賦值變量個(gè)數計數寄存器R1(循環(huán)計數器)初值
MOV DPTR,#initialtab
NEXTINITIAL:
MOV A,R1
MOVC A,@A+DPTR ;查表數據送累加器A
MOV @R0,A
INC R0 ;指針增一
INC R1 ;循環(huán)計數器增一
CJNE R1,#8,NEXTINITIAL ;判給30H-3FH賦初值完否
MAIN:
MOV R0,#30H ;設置十六進(jìn)制數地址指針
MOV R1,#60H ;設置ASCII碼地址指針
MOV R7,#08H ;需拼裝的十六進(jìn)制數字節個(gè)數
MOV DPTR,#ACSIITAB
ABC:
MOV A,@R0 ;取十六進(jìn)制數
MOV B,A ;暫存
ANL A,#0F0H ;取十六進(jìn)制數的字節高4位
RR A ;取十六進(jìn)制數的字節高4位移到字節的低4位
RR A
RR A
RR A
ACALL TRANACSAII ;查表數據送累加器A
MOV @R1,A ;保存轉換結果
INC R1 ;轉換結果指針增一
MOV A,B
ANL A,#0FH ;取十六進(jìn)制數的字節低4位
ACALL TRANACSAII ;查表數據送累加器A
MOV @R1,A ;保存轉換結果
INC R1 ;轉換結果指針增一
INC R0 ;轉換數據指針增一
DJNZ R7,ABC ;繼續
SJMP $
initialtab: ;給30H-37H賦值用初值表
DB 23H,6DH,09H,7FH,8CH,1EH,4BH,5AH
TRANACSAII:
INC A ;查表之前A加1是因為MOVC指令與數據表之間有一個(gè)地址單元的間隔(RET指令)
MOVC A,@A+PC ;由于數據表緊跟MOVC指令之后,因此以PC作為基址寄存器比較方便.
RET
ACSIITAB: ;0～F，對應的ASCII碼表
DB "012345678"
DB "9ABCDEF"
end
其它單片機跟C51查表類(lèi)似.下面介紹松翰的單片機的查表程序.松翰單片機查表是通過(guò)X.Y寄存器來(lái)達到指向的表的目的如下
b0mov z,#segtab$L
b0mov y,#segtab$M
b0mov a,freqh ;led 3
add z,a
b0bts0 fc
incms y;表加1
nop
movc
.................
segtab:
dw 000ch
dw 000ah
dw 000ch ;0
dw 000ch
dw 0000h
dw 0000h ;1
dw 0008h
dw 000eh
dw 0004h ;2
......................
希望看了此文之后.大家對查表的一個(gè)清楚認識
聯(lián)系客服
