突然想起了以前玩電子詞典的數字拼圖這個(gè)小游戲來(lái)消磨時(shí)間，于是就用批處理弄了一個(gè)了，嘻嘻。
支持生成3×3到9×9的數字方陣（9×9的真的是消磨時(shí)間的好東西……）；隨機打亂那些數字的位置，所以是100％可以還原的。
W，S，A，D對應上下左右移動(dòng)空白方格四周的方格，這個(gè)應該很熟悉了吧。
代碼如下（6-23改了一點(diǎn)細節），消磨時(shí)間時(shí)玩玩：
@echo off
title 數字拼圖——by dikex
setlocal enabledelayedexpansion
:INPUT
cls
set /p "n=方陣行數(3-9)?"
set n|findstr /r /x "n=[3-9]" 1>nul 2>nul||goto :INPUT
set /a "nn=%n%*%n%-1"
for /l %%i in (1,1,%nn%) do set "nstr=!nstr! %%i"
call :MARK %nstr% 0
:UPSET
set /a "usn=100*%n%"
for /l %%i in (1,1,%usn%) do (
set /a "rn=!random!%%4"
if "!rn!"=="0" set "rnn=w"
if "!rn!"=="1" set "rnn=s"
if "!rn!"=="2" set "rnn=a"
if "!rn!"=="3" set "rnn=d"
call :MOVE !rnn!
)
call :CHECK
if "%seterr%"=="0" goto :UPSET
:START
cls&echo.
for /l %%y in (1,1,%n%) do (
for /l %%x in (1,1,%n%) do (
if "%%x"=="%n%" (echo+ !p%%y-%%x:~-2,2!&echo.) else set /p= !p%%y-%%x:~-2,2! ^|<nul
)
)
call :CHECK
if "%seterr%"=="0" goto :END
set choice=<nul
set /p choice=選擇(W,S,A,D)?
set choice|findstr /i /r /x "choice=[wsad]" 1>nul 2>nul||goto :START
call :MOVE %choice%
goto :START
:MARK
for /l %%y in (1,1,%n%) do (
for /l %%x in (1,1,%n%) do (
call :MARK2 %%x %%y %%1
shift
)
)
goto :EOF
:MARK2
if "%3"=="0" (set "p%2-%1= "&set "null=%2-%1") else set "p%2-%1= %3"
goto :EOF
:MOVE
set "my=!null:~0,1!"
set "mx=!null:~-1,1!"
if /i "%1"=="w" set /a "my=%my%+1"
if /i "%1"=="s" set /a "my=%my%-1"
if /i "%1"=="a" set /a "mx=%mx%+1"
if /i "%1"=="d" set /a "mx=%mx%-1"
if defined p%my%-%mx% (
set "null=%my%-%mx%"
set "p%null%=!p%my%-%mx%!"&set "p%my%-%mx%= "
)
goto :EOF
:CHECK
set "seterr=0"
set "count=1"
for /l %%y in (1,1,%n%) do (
for /l %%x in (1,1,%n%) do (
if "%%y-%%x"=="%n%-%n%" goto :EOF
if not "!p%%y-%%x: =!"=="!count!" (set "seterr=1"&goto :EOF)
set /a "count+=1"
)
)
goto :EOF
:END
set choice=<nul
set /p "choice=GOOD！再來(lái)一次(Y/N)?"
set choice|findstr /i /r /x "choice=[YN]" 1>nul 2>nul||goto :END
if /i "%choice%"=="y" goto :INPUT
exit
消磨了不少時(shí)間弄好了一個(gè)9×9的！
