『樓 主』: 非常好的for教程，看完這個(gè)保你會(huì )用for
批處理for命令詳解
FOR這條命令基本上都被用來(lái)處理文本,但還有其他一些好用的功能!
看看他的基本格式(這里我引用的是批處理中的格式,直接在命令行只需要一個(gè)%號)
FOR 參數 %%變量名 IN (相關(guān)文件或命令) DO 執行的命令
參數:FOR有4個(gè)參數 /d /l /r /f 他們的作用我在下面用例子解釋
%%變量名 :這個(gè)變量名可以是小寫(xiě)a-z或者大寫(xiě)A-Z,他們區分大小寫(xiě),FOR會(huì )把每個(gè)讀取到的值給他;
IN:命令的格式,照寫(xiě)就是了;
(相關(guān)文件或命令) :FOR要把什么東西讀取然后賦值給變量,看下面的例子
do:命令的格式,照寫(xiě)就是了!
執行的命令:對每個(gè)變量的值要執行什么操作就寫(xiě)在這.
可以在CMD輸入for /?看系統提供的幫助!對照一下
FOR %%variable IN (set) DO command [command-parameters]
%%variable 指定一個(gè)單一字母可替換的參數。
(set) 指定一個(gè)或一組文件?？梢允褂猛ㄅ浞?。
command 指定對每個(gè)文件執行的命令。
command-parameters
為特定命令指定參數或命令行開(kāi)關(guān)。
現在開(kāi)始講每個(gè)參數的意思
/d
僅為目錄
如果 Set (也就是我上面寫(xiě)的 "相關(guān)文件或命令") 包含通配符（* 和 ?），將對與 Set 相匹配的每個(gè)目
錄（而不是指定目錄中的文件組）執行指定的 Command。
系統幫助的格式:FOR /D %%variable IN (set) DO command
他主要用于目錄搜索,不會(huì )搜索文件,看這樣的例子
@echo off
for /d %%i in (*) do @echo %%i
pause
把他保存放在C盤(pán)根目錄執行,就會(huì )把C盤(pán)目錄下的全部目錄名字打印出來(lái),而文件名字一個(gè)也不顯示!
再來(lái)一個(gè),比如我們要把當前路徑下文件夾的名字只有1-3個(gè)字母的打出來(lái)
@echo off
for /d %%i in (???) do @echo %%i
pause
這樣的話(huà)如果你當前目錄下有目錄名字只有1-3個(gè)字母的,就會(huì )顯示出來(lái),沒(méi)有就不顯示了
思考題目:
@echo off
for /d %%i in (window?) do @echo %%i
pause
保存到C盤(pán)下執行,會(huì )顯示什么呢?自己看吧!
/D參數只能顯示當前目錄下的目錄名字,這個(gè)大家要注意!
/R
遞歸
進(jìn)入根目錄樹(shù) [Drive:]Path，在樹(shù)的每個(gè)目錄中執行 for 語(yǔ)句。如果在 /R 后沒(méi)有指定目錄，則認為是
當前目錄。如果 Set 只是一個(gè)句點(diǎn) (.)，則只枚舉目錄樹(shù)。
系統幫助的格式:FOR /R [[drive:]path] %%variable IN (set) DO command
上面我們知道,/D只能顯示當前路徑下的目錄名字,那么現在這個(gè)/R也是和目錄有關(guān),他能干嘛呢?放心他比
/D強大多了!
他可以把當前或者你指定路徑下的文件名字全部讀取,注意是文件名字,有什么用看例子!
@echo off
for /r c:\ %%i in (*.exe) do @echo %%i
pause
咋們把這個(gè)BAT保存到D盤(pán)隨便哪里然后執行,我會(huì )就會(huì )看到,他把C盤(pán)根目錄,和每個(gè)目錄的子目錄下面全部
的EXE文件都列出來(lái)了,這里的c:\就是目錄了。
再來(lái)一個(gè)
@echo off
for /r %%i in (*.exe) do @echo %%i
pause
參數不一樣了，這個(gè)命令前面沒(méi)加那個(gè)C:\也就是搜索路徑,這樣他就會(huì )以當前目錄為搜索路徑,比如你這
個(gè)BAT你把他放在d:\test目錄下執行,那么他就會(huì )把D:\test目錄和他下面的子目錄的全部EXE文件列出
來(lái)!!!
/L
迭代數值范圍
使用迭代變量設置起始值 (Start#)，然后逐步執行一組范圍的值，直到該值超過(guò)所設置的終止值 (End#)
。/L 將通過(guò)對 Start# 與 End# 進(jìn)行比較來(lái)執行迭代變量。如果 Start# 小于 End#，就會(huì )執行該命令。
如果迭代變量超過(guò) End#，則命令解釋程序退出此循環(huán)。還可以使用負的 Step# 以遞減數值的方式逐步執
行此范圍內的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 則生成序列 (5 4 3 2 1)。語(yǔ)法是：
系統幫助的格式:for /L %% Variable in (Start#,Step#,End#) do Command
例如：
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
保存執行看效果,他會(huì )打印從1 2 3 4 5 這樣5個(gè)數字
(1,1,5)這個(gè)參數也就是表示從1開(kāi)始每次加1直到5終止!
再看這個(gè)例子
@echo off
for /l %%i in (1,1,5) do start cmd
pause
執行后是不是嚇了一跳,怎么多了5個(gè)CMD窗口,呵呵!如果把那個(gè) (1,1,5)改成 (1,1,65535)會(huì )有什么結果,
我先告訴大家,會(huì )打開(kāi)65535個(gè)CMD窗口....這么多你不死機算你強!
當然我們也可以把那個(gè)start cmd改成md %%i 這樣就會(huì )建立指定個(gè)目錄了!!!名字為1-65535
看完這個(gè)被我賦予破壞性質(zhì)的參數后,我們來(lái)看最后一個(gè)參數
/f
含有/F的for詳細說(shuō)明
含有/F的for有很大的用處，在批處理中使用的最多，用法如下：
格式：
FOR /F ["options"] %%i IN (file) DO command
FOR /F ["options"] %%i IN ("string") DO command
FOR /F ["options"] %%i IN ('command') DO command
這個(gè)可能是最常用的，也是最強的命令，主要用來(lái)處理文件和一些命令的輸出結果。
file代表一個(gè)或多個(gè)文件
string 代表字符串
command代表命令
["options"] 可選
對于FOR /F %%i IN (file) DO command
file為文件名，按照官方的說(shuō)法是，for會(huì )依次將file中的文件打開(kāi)，并且在進(jìn)行到下一個(gè)文件之前將每個(gè)文件讀取到內存，按照每一行分成一個(gè)一個(gè)的元素，忽略空白的行，看個(gè)例子。
假如文件a.txt中有如下內容：
第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
你想顯示a.txt中的內容，會(huì )用什么命令呢？當然是type，type a.txt
for也可以完成同樣的命令：
for /f %%i in (a.txt) do echo %%i
還是先從括號執行，因為含有參數/f,所以for會(huì )先打開(kāi)a.txt，然后讀出a.txt里面的所有內容，把它作為一個(gè)集合，并且以每一行作為一個(gè)元素，所以會(huì )產(chǎn)生這樣的集合，
{“第1行第1列 第1行第2列 第1行第3列”， //第一個(gè)元素
“第2行第1列 第2行第2列 第2行第3列”， //第二個(gè)元素
“第3行第1列 第3行第2列 第3行第3列”} //第三個(gè)元素
集合中只有3個(gè)元素，同樣用%%i依次代替每個(gè)元素，然后執行do后面的命令。
具體過(guò)程：
用%%i代替“第1行第1列 第1行第2列 第1行第3列”，執行do后面的echo %%i，顯示“第1行第1列 第1行第2列 第1行第3列”，
用%%i代替“第2行第1列 第2行第2列 第2行第3列”，執行echo %%i，顯示“第2行第1列 第2行第2列 第2行第3列”，
依次，直到每個(gè)元素都代替完為止。
為了加強理解/f的作用，請執行一下兩個(gè)命令，對比即可明白：
for /f %%i in (a.txt) do echo %%i //這個(gè)會(huì )顯示a.txt里面的內容，因為/f的作用，會(huì )讀出a.txt中
的內容。
for %%i in (a.txt) do echo %%i //而這個(gè)只會(huì )顯示a.txt這個(gè)名字，并不會(huì )讀取其中的內容。
通過(guò)上面的學(xué)習，我們發(fā)現for /f會(huì )默認以每一行來(lái)作為一個(gè)元素，但是如果我們還想把每一行再分解更小的內容，該怎么辦呢？不用擔心，for命令還為我們提供了更詳細的參數，使我們將每一行分為更小的元素成為可能。
它們就是：delims和tokens
delims 用來(lái)告訴for每一行應該拿什么作為分隔符，默認的分隔符是空格和tab鍵
比如，還是上面的文件，我們執行下面的命令：
for /f "delims= " %%i in (a.txt) do echo %%i
顯示的結果是：
第1行第1列
第2行第1列
第3行第1列
為什么是這樣的呢。因為這里有了delims這個(gè)參數，=后面有一個(gè)空格，意思是再將每個(gè)元素以空格分割，默認是只取分割之后的第一個(gè)元素。
執行過(guò)程是：
將第一個(gè)元素“第1行第1列 第1行第2列 第1行第3列”分成三個(gè)元素：“第1行第1列” “第1行第2列” “第1行第3列”，它默認只取第一個(gè)，即“第1行第1列”，然后執行do后面的命令，依次類(lèi)推。
但是這樣還是有局限的，如果我們想要每一行的第二列元素，那又如何呢？
這時(shí)候，tokens跳出來(lái)說(shuō)，我能做到。
它的作用就是當你通過(guò)delims將每一行分為更小的元素時(shí)，由它來(lái)控制要取哪一個(gè)或哪幾個(gè)。
還是上面的例子，執行如下命令：
for /f "tokens=2 delims= " %%i in (a.txt) do echo %%i
執行結果：
第1行第2列
第2行第2列
第3行第2列
如果要顯示第三列，那就換成tokens=3。
同時(shí)tokens支持通配符*，以及限定范圍。
如果要顯示第二列和第三列，則換成tokens=2,3或tokens=2-3,如果還有更多的則為：tokens=2-10之類(lèi)的。
此時(shí)的命令為：
for /f "tokens=2,3 delims= " %%i in (a.txt) do echo %%i %%j
怎么多出一個(gè)%%j？
這是因為你的tokens后面要取每一行的兩列，用%%i來(lái)替換第二列，用%%j來(lái)替換第三列。
并且必須是按照英文字母順序排列的，%%j不能換成%%k，因為i后面是j
執行結果為：
第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列
對以通配符*，就是把這一行全部或者這一行的剩余部分當作一個(gè)元素了。
比如：
for /f "tokens=* delims= " %%i in (a.txt) do echo %%i
執行結果為：
第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
其實(shí)就跟for /f %%i in (a.txt) do echo %%i的執行結果是一樣的。
再如：
for /f "tokens=2,* delims= " %%i in (a.txt) do echo %%i %%j
執行結果為：
第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列
用%%i代替第二列，用%%j代替剩余的所有
最后還有skip和eol，這倆個(gè)簡(jiǎn)單，skip就是要忽略文件的前多少行，而eol用來(lái)指定當一行以什么符號開(kāi)始時(shí)，就忽略它。
比如：
for /f "skip=2 tokens=*" %%i in (a.txt) do echo %%i
結果為:
第3行第1列 第3行第2列 第3行第3列
用skip來(lái)告訴for跳過(guò)前兩行。
如果不加tokens=*的話(huà)，執行結果為：
第3行第1列
不知道怎么回事。
再如，當a.txt內容變成：
.第1行第1列 第1行第2列 第1行第3列
.第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
執行for /f "eol=. tokens=*" %%i in (a.txt) do echo %%i結果是：
第3行第1列 第3行第2列 第3行第3列
用eol來(lái)告訴for忽略以“.”開(kāi)頭的行。
同樣也必須加tokens=*，否則只會(huì )顯示“第3行第1列
最強之dos命令 – for (是新手學(xué)習FOR語(yǔ)句的好資料)
這篇文章是網(wǎng)上找的，很多初學(xué)DOS的朋友對FOR語(yǔ)句掌握的好不是太過(guò)熟悉，希望這邊文章能夠給你開(kāi)闊思路幫助你把FOR語(yǔ)句學(xué)好，主要的參數介紹和實(shí)例講的都很清楚，也希望對DOS越來(lái)越感興趣－－－＞發(fā)揮你的想像力吧
正文開(kāi)始
以前常覺(jué)得DOS的命令行功能太弱，無(wú)法象UNIX一樣可以用命令行完成非常復雜的操作。實(shí)際上，當MS從WIN2K開(kāi)始將命令行增強后，已經(jīng)借鑒了相當多UNIX的優(yōu)點(diǎn)，雖然還無(wú)法做到象UNIX那么靈活，但已可完成絕大多數的任務(wù)，比如用&&和 連接兩個(gè)（或更多）命令，由前一個(gè)的返回值來(lái)決定下一個(gè)是否執行，等等。而在這些增強中，最明顯的，就是FOR命令。
舉個(gè)例子，用適當的參數，可用FOR命令將 date /t 的輸出 從 "Sat 07/13/2002" 變成你想要的格式，比如， "2002-07-13"：
c:\>for /f "tokens=2,3,4 delims=/ " %a in ('date /t') do @echo %c-%a-%b
2002-07-13
該例將在（3）中詳細說(shuō)明。
0. 基本應用
簡(jiǎn)單說(shuō)，FOR是個(gè)循環(huán)，可以用你指定的循環(huán)范圍生成一系列命令。最簡(jiǎn)單的例子，就是人工指定循環(huán)范圍，然后對每個(gè)值執行指定的命令。例如，想快速報告每個(gè)硬盤(pán)分區的剩余空間：
for %a in (c: d: e: f do @dir %a\ find "bytes free"
將輸出：
8 Dir(s) 1,361,334,272 bytes free
15 Dir(s) 8,505,581,568 bytes free
12 Dir(s) 12,975,149,056 bytes free
7 Dir(s) 11,658,854,400 bytes free
用它可以使一些不支持通配符的命令對一系列文件進(jìn)行操作。在WIN9X中，TYPE命令（顯示文件內容）是不支持*.txt這種格式的（WIN2K開(kāi)始TYPE已支持通配）。遇到類(lèi)似情況就可以用FOR：
for %a in (*.txt) do type %a
這些還不是FOR最強大的功能。我認為它最強大的功能，表現在以下這些高級應用：
1. 可以用 /r 參數遍歷整個(gè)目錄樹(shù)
2. 可以用 /f 參數將文本文件內容作為循環(huán)范圍
3. 可以用 /f 參數將某一命令執行結果作為循環(huán)范圍
4. 可以用 %~ 操作符將文件名分離成文件名、擴展名、盤(pán)符等獨立部分
現分別舉例說(shuō)明如下：
1. 用 /r 遍歷目錄樹(shù)
當用 *.* 或 *.txt 等文件名通配符作為 for /r 的循環(huán)范圍時(shí)，可以對當前目錄下所有文件（包括子目錄里面的文件）進(jìn)行操作。舉個(gè)例子，你想在當前目錄的所有txt文件（包括子目錄）內容中查找"bluebear"字樣，但由于find本身不能遍歷子目錄，所以我們用for:
for /r . %a in (*.txt) do @find "bluebear" %a
find 前面的 @ 只是讓輸出結果不包括 find 命令本身。這是DOS很早就有的功能。和FOR無(wú)關(guān)。
當用 . 作為循環(huán)范圍時(shí)，for 只將子目錄的結構（目錄名）作為循環(huán)范圍，而不包括里面的文件。有點(diǎn)象 TREE 命令，不過(guò)側重點(diǎn)不同。TREE 的重點(diǎn)是用很漂亮易讀的格式輸出，而FOR的輸出適合一些自動(dòng)任務(wù)，例如，我們都知道用CVS管理的項目中，每個(gè)子目錄下都會(huì )有一個(gè)CVS目錄，有時(shí)在軟件發(fā)行時(shí)我們想把這些CVS目錄全部去掉：
for /r . %a in (.) do @if exist %a\CVS rd /s /q %a\CVS
先用 if exist 判斷一下，是因為 for 只是機械的對每個(gè)目錄進(jìn)行列舉，如果有些目錄下面沒(méi)有CVS也會(huì )被執行到。用 if exist 判斷一下比較安全。
這種刪除命令威力太大，請小心使用。最好是在真正執行以上的刪除命令前，將 rd /s /q 換成 @echo 先列出要刪出的目錄，確認無(wú)誤后再換回rd /s /q：
for /r . %a in (.) do @if exist %a\CVS @echo %a\CVS
可能目錄中會(huì )多出一層 "."，比如 c:\proj\release\.\CVS ，但不會(huì )影響命令的執行效果。
2. 將某一文件內容或命令執行結果作為循環(huán)范圍：
假如你有一個(gè)文件 todel.txt，里面是所有要刪除的文件列表，現在你想將里面列出的每個(gè)文件都刪掉。假設這個(gè)文件是每個(gè)文件名占一行，象這樣：
c:\temp\a1.txt
c:\temp\a2.txt
c:\temp\subdir\b3.txt
c:\temp\subdir\b4.txt
那么可以用FOR來(lái)完成：
for /f %a in (todel.txt) do del %a
這個(gè)命令還可以更強大。比如你的 todel.txt 并不是象上面例子那么干凈，而是由DIR直接生成，有一些沒(méi)用的信息，比如這樣：
Volume in drive D is DATA
Volume Serial Number is C47C-9908
Directory of D:\tmp
09/26/2001 12:50 PM 18,426 alg0925.txt
12/02/2001 04:29 AM 795 bsample.txt
04/11/2002 04:18 AM 2,043 invitation.txt
4 File(s) 25,651 bytes
0 Dir(s) 4,060,700,672 bytes free
for 仍然可以解出其中的文件名并進(jìn)行操作：
for /f "skip=5 tokens=5" %a in (todel.txt) do @if exist %a DEL %a
當然，上面這個(gè)命令是在進(jìn)行刪除，如果你只是想看看哪些文件將被操作，把DEL換成echo:
for /f "skip=5 tokens=5" %a in (todel.txt) do @if exist %a echo %a
你將看到：
alg0925.txt
bsample.txt
invitation.txt
skip=5表示跳過(guò)前5行（就是DIR輸出的頭部信息），tokens=5表示將每行的第5列作為循環(huán)值放入%a，正好是文件名。在這里我加了一個(gè)文件存在判斷，是因為最后一行的"free"剛好也是第5列，目前還想不出好的辦法來(lái)濾掉最后兩行，所以檢查一下可保萬(wàn)無(wú)一失。
3. 可以用 /f 參數將某一命令執行結果作為循環(huán)范圍
非常有用的功能。比如，我們想知道目前的環(huán)境變量有哪些名字（我們只要名字，不要值）?？墒荢ET命令的輸出是“名字=值”的格式，現在可以用FOR來(lái)只取得名字部分：
FOR /F "delims==" %i IN ('set') DO @echo %i
將看到：
ALLUSERSPROFILE
APPDATA
CLASSPATH
CommonProgramFiles
COMPUTERNAME
ComSpec
dircmd
HOMEDRIVE
......
這里是將set命令執行的結果拿來(lái)作為循環(huán)范圍。delims==表示用=作為分隔符，由于FOR /F默認是用每行第一個(gè)TOKEN，所以可以分離出變量名。如果是想僅列出值：
FOR /F "delims== tokens=2" %i IN ('set') DO @echo %i
tokens=2和前例相同，表示將第二列（由=作為分隔符）作為循環(huán)值。
再來(lái)個(gè)更有用的例子：
我們知道 date /t （/t表示不要詢(xún)問(wèn)用戶(hù)輸入）的輸出是象這樣的：
Sat 07/13/2002
現在我想分離出日期部分，也就是13：
for /f "tokens=3 delims=/ " %a in ('date /t') do @echo %a
實(shí)際上把 tokens后面換成1,2,3或4，你將分別得到Sat, 07, 13和2002。注意delims=/后面還有個(gè)空格，表示/和空格都是分隔符。由于這個(gè)空格delims必須是/f選項的最后一項。
再靈活一點(diǎn)，象本文開(kāi)頭提到的，將日期用2002-07-13的格式輸出：
for /f "tokens=2,3,4 delims=/ " %a in ('date /t') do @echo %c-%a-%b
當tokens后跟多個(gè)值時(shí)，將分別映射到%a, %b, %c等。實(shí)際上跟你指定的變量有關(guān)，如果你指定的是 %i, 它們就會(huì )用%i, %j, %k等。
靈活應用這一點(diǎn)，幾乎沒(méi)有做不了的事。
4. 可以用 %~ 操作符將文件名分離成文件名、擴展名、盤(pán)符等獨立部分
這個(gè)比較簡(jiǎn)單，就是說(shuō)將循環(huán)變量的值自動(dòng)分離成只要文件名，只要擴展名，或只要盤(pán)符等等。
例：要將 c:\mp3下所有mp3的歌名列出，如果用一般的 dir /b/s 或 for /r ，將會(huì )是這樣：
g:\mp3\Archived\05-18-01-A\游鴻明-下沙\游鴻明-01 下沙.mp3
g:\mp3\Archived\05-18-01-A\游鴻明-下沙\游鴻明-02 21個(gè)人.mp3
......
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-阿修羅.mp3
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-彼岸花.mp3
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-不愛(ài)我的我不愛(ài).mp3
......
如果我只要歌名（不要路徑和".mp3"）：
游鴻明-01 下沙
游鴻明-02 21個(gè)人
......
王菲-阿修羅
王菲-彼岸花
王菲-不愛(ài)我的我不愛(ài)
......
那么可以用FOR命令：
for /r g:\mp3 %a in (*.mp3) do @echo %~na
凡是 %~ 開(kāi)頭的操作符，都是文件名的分離操作。具體請看 for /? 幫助。
本文舉的例子有些可能沒(méi)有實(shí)際用處，或可用其它辦法完成。僅用于體現FOR可以不借助其它工具，僅用DOS命令組合，就可完成相當靈活的任務(wù)
