Linux下AT&T匯編語(yǔ)法格式簡(jiǎn)介
AT&T 格式Linux 匯編語(yǔ)法格式
在 AT&T 匯編格式中，寄存器名要加上 ‘%‘ 作為前綴；而在 Intel 匯編格式中，寄存器名不需要加前綴。例如：
AT&T 格式
Intel 格式
pushl %eax
push eax
在 AT&T 匯編格式中，用 ‘$‘ 前綴表示一個(gè)立即操作數；而在 Intel 匯編格式中，立即數的表示不用帶任何前綴。例如：
AT&T 格式
Intel 格式
pushl $1
push 1
AT&T 和 Intel 格式中的源操作數和目標操作數的位置正好相反。在 Intel 匯編格式中，目標操作數在源操作數的左邊；而在 AT&T 匯編格式中，目標操作數在源操作數的右邊。例如：
AT&T 格式
Intel 格式
addl $1, %eax
add eax, 1
在 AT&T 匯編格式中，操作數的字長(cháng)由操作符的最后一個(gè)字母決定，后綴‘b‘、‘w‘、‘l‘分別表示操作數為字節（byte，8 比特）、字（word，16 比特）和長(cháng)字（long，32比特）；而在 Intel 匯編格式中，操作數的字長(cháng)是用 "byte ptr" 和 "word ptr" 等前綴來(lái)表示的。例如：
AT&T 格式
Intel 格式
movb val, %al
mov al, byte ptr val
在 AT&T 匯編格式中，絕對轉移和調用指令（jump/call）的操作數前要加上‘*‘作為前綴，而在 Intel 格式中則不需要。
遠程轉移指令和遠程子調用指令的操作碼，在 AT&T 匯編格式中為 "ljump" 和 "lcall"，而在 Intel 匯編格式中則為 "jmp far" 和 "call far"，即：
AT&T 格式
Intel 格式
ljump $section, $offset
jmp far section:offset
lcall $section, $offset
call far section:offset
與之相應的遠程返回指令則為：
AT&T 格式
Intel 格式
lret $stack_adjust
ret far stack_adjust
在 AT&T 匯編格式中，內存操作數的尋址方式是
section:disp(base, index, scale)
而在 Intel 匯編格式中，內存操作數的尋址方式為：
section:[base + index*scale + disp]
由于 Linux 工作在保護模式下，用的是 32 位線(xiàn)性地址，所以在計算地址時(shí)不用考慮段基址和偏移量，而是采用如下的地址計算方法：
disp + base + index * scale
下面是一些內存操作數的例子：
AT&T 格式
Intel 格式
movl -4(%ebp), %eax
mov eax, [ebp - 4]
movl array(, %eax, 4), %eax
mov eax, [eax*4 + array]
movw array(%ebx, %eax, 4), %cx
mov cx, [ebx + 4*eax + array]
movb $4, %fs:(%eax)
mov fs:eax, 4
Hello World!
既然所有程序設計語(yǔ)言的第一個(gè)例子都是在屏幕上打印一個(gè)字符串 "Hello World!"，那我們也以這種方式來(lái)開(kāi)始介紹 Linux 下的匯編語(yǔ)言程序設計。
在 Linux 操作系統中，你有很多辦法可以實(shí)現在屏幕上顯示一個(gè)字符串，但最簡(jiǎn)潔的方式是使用 Linux 內核提供的系統調用。使用這種方法最大的好處是可以直接和操作系統的內核進(jìn)行通訊，不需要鏈接諸如 libc 這樣的函數庫，也不需要使用 ELF 解釋器，因而代碼尺寸小且執行速度快。
Linux 是一個(gè)運行在保護模式下的 32 位操作系統，采用 flat memory 模式，目前最常用到的是 ELF 格式的二進(jìn)制代碼。一個(gè) ELF 格式的可執行程序通常劃分為如下幾個(gè)部分：.text、.data 和 .bss，其中 .text 是只讀的代碼區，.data 是可讀可寫(xiě)的數據區，而 .bss 則是可讀可寫(xiě)且沒(méi)有初始化的數據區。代碼區和數據區在 ELF 中統稱(chēng)為 section，根據實(shí)際需要你可以使用其它標準的 section，也可以添加自定義 section，但一個(gè) ELF 可執行程序至少應該有一個(gè) .text 部分。下面給出我們的第一個(gè)匯編程序，用的是 AT&T 匯編語(yǔ)言格式：
例1. AT&T 格式
#hello.s
.data # 數據段聲明
msg : .string "Hello, world!\\n" # 要輸出的字符串
len = . - msg # 字串長(cháng)度
.text # 代碼段聲明
.global _start # 指定入口函數
_start: # 在屏幕上顯示一個(gè)字符串
movl $len, %edx # 參數三：字符串長(cháng)度
movl $msg, %ecx # 參數二：要顯示的字符串
movl $1, %ebx # 參數一：文件描述符(stdout)
movl $4, %eax # 系統調用號(sys_write)
int $0x80 # 調用內核功能
# 退出程序
movl $0,%ebx # 參數一：退出代碼
movl $1,%eax # 系統調用號(sys_exit)
int $0x80 # 調用內核功能
初次接觸到 AT&T 格式的匯編代碼時(shí)，很多程序員都認為太晦澀難懂了，沒(méi)有關(guān)系，在 Linux 平臺上你同樣可以使用 Intel 格式來(lái)編寫(xiě)匯編程序：
例2. Intel 格式
; hello.asm
section .data ; 數據段聲明
msg db "Hello, world!", 0xA ; 要輸出的字符串
len equ $ - msg ; 字串長(cháng)度
section .text ; 代碼段聲明
global _start ; 指定入口函數
_start: ; 在屏幕上顯示一個(gè)字符串
mov edx, len ; 參數三：字符串長(cháng)度
mov ecx, msg ; 參數二：要顯示的字符串
mov ebx, 1 ; 參數一：文件描述符(stdout)
mov eax, 4 ; 系統調用號(sys_write)
int 0x80 ; 調用內核功能
; 退出程序
mov ebx, 0 ; 參數一：退出代碼
mov eax, 1 ; 系統調用號(sys_exit)
int 0x80 ; 調用內核功能
上 面兩個(gè)匯編程序采用的語(yǔ)法雖然完全不同，但功能卻都是調用 Linux 內核提供的 sys_write 來(lái)顯示一個(gè)字符串，然后再調用 sys_exit 退出程序。在 Linux 內核源文件 include/asm-i386/unistd.h 中，可以找到所有系統調用的定義。
Linux 匯編工具
Linux 平臺下的匯編工具雖然種類(lèi)很多，但同 DOS/Windows 一樣，最基本的仍然是匯編器、連接器和調試器。
1. 匯編器
匯 編器（assembler）的作用是將用匯編語(yǔ)言編寫(xiě)的源程序轉換成二進(jìn)制形式的目標代碼。Linux 平臺的標準匯編器是 GAS，它是 GCC 所依賴(lài)的后臺匯編工具，通常包含在 binutils 軟件包中。GAS 使用標準的 AT&T 匯編語(yǔ)法，可以用來(lái)匯編用 AT&T 格式編寫(xiě)的程序：
[xiaowp@gary code]$ as -o hello.o hello.s
Linux 平臺上另一個(gè)經(jīng)常用到的匯編器是 NASM，它提供了很好的宏指令功能，并能夠支持相當多的目標代碼格式，包括 bin、a.out、coff、elf、rdf 等。NASM 采用的是人工編寫(xiě)的語(yǔ)法分析器，因而執行速度要比 GAS 快很多，更重要的是它使用的是 Intel 匯編語(yǔ)法，可以用來(lái)編譯用 Intel 語(yǔ)法格式編寫(xiě)的匯編程序：
[xiaowp@gary code]$ nasm -f elf hello.asm
2. 鏈接器
由 匯編器產(chǎn)生的目標代碼是不能直接在計算機上運行的，它必須經(jīng)過(guò)鏈接器的處理才能生成可執行代碼。鏈接器通常用來(lái)將多個(gè)目標代碼連接成一個(gè)可執行代碼，這樣 可以先將整個(gè)程序分成幾個(gè)模塊來(lái)單獨開(kāi)發(fā)，然后才將它們組合(鏈接)成一個(gè)應用程序。 Linux 使用 ld 作為標準的鏈接程序，它同樣也包含在 binutils 軟件包中。匯編程序在成功通過(guò) GAS 或 NASM 的編譯并生成目標代碼后，就可以使用 ld 將其鏈接成可執行程序了：
[xiaowp@gary code]$ ld -s -o hello hello.o
3. 調試器
有 人說(shuō)程序不是編出來(lái)而是調出來(lái)的，足見(jiàn)調試在軟件開(kāi)發(fā)中的重要作用，在用匯編語(yǔ)言編寫(xiě)程序時(shí)尤其如此。Linux 下調試匯編代碼既可以用 GDB、DDD 這類(lèi)通用的調試器，也可以使用專(zhuān)門(mén)用來(lái)調試匯編代碼的 ALD(Assembly Language Debugger)。
從調試的角度來(lái)看，使用 GAS 的好處是可以在生成的目標代碼中包含符號表(symbol table)，這樣就可以使用 GDB 和 DDD 來(lái)進(jìn)行源碼級的調試了。要在生成的可執行程序中包含符號表，可以采用下面的方式進(jìn)行編譯和鏈接：
[xiaowp@gary code]$ as --gstabs -o hello.o hello.s
[xiaowp@gary code]$ ld -o hello hello.o
執行 as 命令時(shí)帶上參數 --gstabs 可以告訴匯編器在生成的目標代碼中加上符號表，同時(shí)需要注意的是，在用 ld 命令進(jìn)行鏈接時(shí)不要加上 -s 參數，否則目標代碼中的符號表在鏈接時(shí)將被刪去。
匯編程序員通常面對的都是一些比較苛刻的軟硬件環(huán)境，短小精悍的ALD可能更能符合實(shí)際的需要，因此下面主要介紹一下如何用ALD來(lái)調試匯編程序。首先在命令行方式下執行ald命令來(lái)啟動(dòng)調試器，該命令的參數是將要被調試的可執行程序：
[xiaowp@gary doc]$ ald hello
Assembly Language Debugger 0.1.3
Copyright (C) 2000-2002 Patrick Alken
hell ELF Intel 80386 (32 bit), LSB, Executable, Version 1 (current)
Loading debugging symbols...(15 symbols loaded)
ald>
當 ALD 的提示符出現之后，用 disassemble 命令對代碼段進(jìn)行反匯編：
ald> disassemble -s .text
Disassembling section .text (0x08048074 - 0x08048096)
08048074 BA0F000000 mov edx, 0xf
08048079 B998900408 mov ecx, 0x8049098
0804807E BB01000000 mov ebx, 0x1
08048083 B804000000 mov eax, 0x4
08048088 CD80 int 0x80
0804808A BB00000000 mov ebx, 0x0
0804808F B801000000 mov eax, 0x1
08048094 CD80 int 0x80
上述輸出信息的第一列是指令對應的地址碼，利用它可以設置在程序執行時(shí)的斷點(diǎn)：
ald> break 0x08048088
Breakpoint 1 set for 0x08048088
斷點(diǎn)設置好后，使用 run 命令開(kāi)始執行程序。ALD 在遇到斷點(diǎn)時(shí)將自動(dòng)暫停程序的運行，同時(shí)會(huì )顯示所有寄存器的當前值：
ald> run
Starting program: hello
Breakpoint 1 encountered at 0x08048088
eax = 0x00000004 ebx = 0x00000001 ecx = 0x08049098 edx = 0x0000000F
esp = 0xBFFFF6C0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000
ds = 0x0000002B es = 0x0000002B fs = 0x00000000 gs = 0x00000000
ss = 0x0000002B cs = 0x00000023 eip = 0x08048088 eflags = 0x00000246
Flags: PF ZF IF
08048088 CD80 int 0x80
如果需要對匯編代碼進(jìn)行單步調試，可以使用 next 命令：
ald> next
Hello, world!
eax = 0x0000000F ebx = 0x00000000 ecx = 0x08049098 edx = 0x0000000F
esp = 0xBFFFF6C0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000
ds = 0x0000002B es = 0x0000002B fs = 0x00000000 gs = 0x00000000
ss = 0x0000002B cs = 0x00000023 eip = 0x0804808F eflags = 0x00000346
Flags: PF ZF TF IF
0804808F B801000000 mov eax, 0x1
若想獲得 ALD 支持的所有調試命令的詳細列表，可以使用 help 命令：
ald> help
Commands may be abbreviated.
If a blank command is entered, the last command is repeated.
Type `help <command>‘‘ for more specific information on <command>.
General commands
attach clear continue detach disassemble
enter examine file help load
next quit register run set
step unload window write
Breakpoint related commands
break delete disable enable ignore
lbreak tbreak
即 便是最簡(jiǎn)單的匯編程序，也難免要用到諸如輸入、輸出以及退出等操作，而要進(jìn)行這些操作則需要調用操作系統所提供的服務(wù)，也就是系統調用。除非你的程序只完 成加減乘除等數學(xué)運算，否則將很難避免使用系統調用，事實(shí)上除了系統調用不同之外，各種操作系統的匯編編程往往都是很類(lèi)似的。
在 Linux 平臺下有兩種方式來(lái)使用系統調用：利用封裝后的 C 庫（libc）或者通過(guò)匯編直接調用。其中通過(guò)匯編語(yǔ)言來(lái)直接調用系統調用，是最高效地使用 Linux 內核服務(wù)的方法，因為最終生成的程序不需要與任何庫進(jìn)行鏈接，而是直接和內核通信。
和 DOS 一樣，Linux 下的系統調用也是通過(guò)中斷（int 0x80）來(lái)實(shí)現的。在執行 int 80 指令時(shí)，寄存器 eax 中存放的是系統調用的功能號，而傳給系統調用的參數則必須按順序放到寄存器 ebx，ecx，edx，esi，edi 中，當系統調用完成之后，返回值可以在寄存器 eax 中獲得。
所有 的系統調用功能號都可以在文件 /usr/include/bits/syscall.h 中找到，為了便于使用，它們是用 SYS_<name> 這樣的宏來(lái)定義的，如 SYS_write、SYS_exit 等。例如，經(jīng)常用到的 write 函數是如下定義的：
ssize_t write(int fd, const void *buf, size_t count);
該 函數的功能最終是通過(guò) SYS_write 這一系統調用來(lái)實(shí)現的。根據上面的約定，參數 fb、buf 和 count 分別存在寄存器 ebx、ecx 和 edx 中，而系統調用號 SYS_write 則放在寄存器 eax 中，當 int 0x80 指令執行完畢后，返回值可以從寄存器 eax 中獲得。
或許你已經(jīng)發(fā)現，在進(jìn)行系統調用時(shí)至多只有 5 個(gè)寄存器能夠用來(lái)保存參數，難道所有系統調用的參數個(gè)數都不超過(guò) 5 嗎？當然不是，例如 mmap 函數就有 6 個(gè)參數，這些參數最后都需要傳遞給系統調用 SYS_mmap：
void * mmap(void *start, size_t length, int prot , int flags, int fd, off_t offset);c
當 一個(gè)系統調用所需的參數個(gè)數大于 5 時(shí)，執行int 0x80 指令時(shí)仍需將系統調用功能號保存在寄存器 eax 中，所不同的只是全部參數應該依次放在一塊連續的內存區域里，同時(shí)在寄存器 ebx 中保存指向該內存區域的指針。系統調用完成之后，返回值仍將保存在寄存器 eax 中。
由 于只是需要一塊連續的內存區域來(lái)保存系統調用的參數，因此完全可以像普通的函數調用一樣使用棧(stack)來(lái)傳遞系統調用所需的參數。但要注意一點(diǎn)， Linux 采用的是 C 語(yǔ)言的調用模式，這就意味著(zhù)所有參數必須以相反的順序進(jìn)棧，即最后一個(gè)參數先入棧，而第一個(gè)參數則最后入棧。如果采用棧來(lái)傳遞系統調用所需的參數，在執行 int 0x80 指令時(shí)還應該將棧指針的當前值復制到寄存器 ebx中。
在 Linux 操作系統中，當一個(gè)可執行程序通過(guò)命令行啟動(dòng)時(shí)，其所需的參數將被保存到棧中：首先是 argc，然后是指向各個(gè)命令行參數的指針數組 argv，最后是指向環(huán)境變量的指針數據 envp。在編寫(xiě)匯編語(yǔ)言程序時(shí)，很多時(shí)候需要對這些參數進(jìn)行處理，下面的代碼示范了如何在匯編代碼中進(jìn)行命令行參數的處理：
例3. 處理命令行參數
# args.s
.text
.globl _start
_start:
popl %ecx # argc
vnext:
popl %ecx # argv
test %ecx, %ecx # 空指針表明結束
jz exit
movl %ecx, %ebx
xorl %edx, %edx
strlen:
movb (%ebx), %al
inc %edx
inc %ebx
test %al, %al
jnz strlen
movb $10, -1(%ebx)
movl $4, %eax # 系統調用號(sys_write)
movl $1, %ebx # 文件描述符(stdout)
int $0x80
jmp vnext
exit: movl $1,%eax # 系統調用號(sys_exit)
xorl %ebx, %ebx # 退出代碼
int $0x80
ret
GCC 內聯(lián)匯編
用 匯編編寫(xiě)的程序雖然運行速度快，但開(kāi)發(fā)速度非常慢，效率也很低。如果只是想對關(guān)鍵代碼段進(jìn)行優(yōu)化，或許更好的辦法是將匯編指令嵌入到 C 語(yǔ)言程序中，從而充分利用高級語(yǔ)言和匯編語(yǔ)言各自的特點(diǎn)。但一般來(lái)講，在 C 代碼中嵌入匯編語(yǔ)句要比"純粹"的匯編語(yǔ)言代碼復雜得多，因為需要解決如何分配寄存器，以及如何與C代碼中的變量相結合等問(wèn)題。
GCC 提供了很好的內聯(lián)匯編支持，最基本的格式是：
__asm__("asm statements");
例如：
__asm__("nop");
如果需要同時(shí)執行多條匯編語(yǔ)句，則應該用"\\n\\t"將各個(gè)語(yǔ)句分隔開(kāi)，例如：
__asm__( "pushl %%eax \\n\\t"
"movl $0, %%eax \\n\\t"
"popl %eax");
通常嵌入到 C 代碼中的匯編語(yǔ)句很難做到與其它部分沒(méi)有任何關(guān)系，因此更多時(shí)候需要用到完整的內聯(lián)匯編格式：
__asm__("asm statements" : outputs : inputs : registers-modified);
插入到 C 代碼中的匯編語(yǔ)句是以":"分隔的四個(gè)部分，其中第一部分就是匯編代碼本身，通常稱(chēng)為指令部，其格式和在匯編語(yǔ)言中使用的格式基本相同。指令部分是必須的，而其它部分則可以根據實(shí)際情況而省略。
在將匯編語(yǔ)句嵌入到C代碼中時(shí)，操作數如何與C代碼中的變量相結合是個(gè)很大的問(wèn)題。GCC采用如下方法來(lái)解決這個(gè)問(wèn)題：程序員提供具體的指令，而對寄存器的使用則只需給出"樣板"和約束條件就可以了，具體如何將寄存器與變量結合起來(lái)完全由GCC和GAS來(lái)負責。
在GCC 內聯(lián)匯編語(yǔ)句的指令部中，加上前綴‘‘%‘‘的數字(如%0，%1)表示的就是需要使用寄存器的"樣板"操作數。指令部中使用了幾個(gè)樣板操作數，就表明有 幾個(gè)變量需要與寄存器相結合，這樣GCC和GAS在編譯和匯編時(shí)會(huì )根據后面給定的約束條件進(jìn)行恰當的處理。由于樣板操作數也使用‘‘ %‘‘作為前綴，因此在涉及到具體的寄存器時(shí)，寄存器名前面應該加上兩個(gè)‘‘%‘‘，以免產(chǎn)生混淆。
緊 跟在指令部后面的是輸出部，是規定輸出變量如何與樣板操作數進(jìn)行結合的條件，每個(gè)條件稱(chēng)為一個(gè)"約束"，必要時(shí)可以包含多個(gè)約束，相互之間用逗號分隔開(kāi)就 可以了。每個(gè)輸出約束都以‘‘=‘‘號開(kāi)始，然后緊跟一個(gè)對操作數類(lèi)型進(jìn)行說(shuō)明的字后，最后是如何與變量相結合的約束。凡是與輸出部中說(shuō)明的操作數相結合 的寄存器或操作數本身，在執行完嵌入的匯編代碼后均不保留執行之前的內容，這是GCC在調度寄存器時(shí)所使用的依據。
輸 出部后面是輸入部，輸入約束的格式和輸出約束相似，但不帶‘‘=‘‘號。如果一個(gè)輸入約束要求使用寄存器，則GCC在預處理時(shí)就會(huì )為之分配一個(gè)寄存器，并 插入必要的指令將操作數裝入該寄存器。與輸入部中說(shuō)明的操作數結合的寄存器或操作數本身，在執行完嵌入的匯編代碼后也不保留執行之前的內容。
有時(shí)在進(jìn)行某些操作時(shí)，除了要用到進(jìn)行數據輸入和輸出的寄存器外，還要使用多個(gè)寄存器來(lái)保存中間計算結果，這樣就難免會(huì )破壞原有寄存器的內容。在GCC內聯(lián)匯編格式中的最后一個(gè)部分中，可以對將產(chǎn)生副作用的寄存器進(jìn)行說(shuō)明，以便GCC能夠采用相應的措施。
下面是一個(gè)內聯(lián)匯編的簡(jiǎn)單例子：
例4.內聯(lián)匯編
/* inline.c */
int main()
{
int a = 10, b = 0;
__asm__ __volatile__("movl %1, %%eax;\\n\\r"
"movl %%eax, %0;"
:"=r"(b) /* 輸出 */
:"r"(a) /* 輸入 */
:"%eax"); /* 不受影響的寄存器 */
printf("Result: %d, %d\\n", a, b);
}
上面的程序完成將變量a的值賦予變量b，有幾點(diǎn)需要說(shuō)明：
變量b是輸出操作數，通過(guò)%0來(lái)引用，而變量a是輸入操作數，通過(guò)%1來(lái)引用。
輸入操作數和輸出操作數都使用r進(jìn)行約束，表示將變量a和變量b存儲在寄存器中。輸入約束和輸出約束的不同點(diǎn)在于輸出約束多一個(gè)約束修飾符‘‘=‘‘。
在內聯(lián)匯編語(yǔ)句中使用寄存器eax時(shí)，寄存器名前應該加兩個(gè)‘‘%‘‘，即%%eax。內聯(lián)匯編中使用%0、%1等來(lái)標識變量，任何只帶一個(gè)‘‘%‘‘的標識符都看成是操作數，而不是寄存器。
內聯(lián)匯編語(yǔ)句的最后一個(gè)部分告訴GCC它將改變寄存器eax中的值，GCC在處理時(shí)不應使用該寄存器來(lái)存儲任何其它的值。
由于變量b被指定成輸出操作數，當內聯(lián)匯編語(yǔ)句執行完畢后，它所保存的值將被更新。
在 內聯(lián)匯編中用到的操作數從輸出部的第一個(gè)約束開(kāi)始編號，序號從0開(kāi)始，每個(gè)約束記數一次，指令部要引用這些操作數時(shí)，只需在序號前加上‘‘%‘‘作為前綴 就可以了。需要注意的是，內聯(lián)匯編語(yǔ)句的指令部在引用一個(gè)操作數時(shí)總是將其作為32位的長(cháng)字使用，但實(shí)際情況可能需要的是字或字節，因此應該在約束中指明 正確的限定符：
限定符
意義
"m"、"v"、"o"
內存單元
"r"
任何寄存器
"q"
寄存器eax、ebx、ecx、edx之一
"i"、"h"
直接操作數
"E"和"F"
浮點(diǎn)數
"g"
任意
"a"、"b"、"c"、"d"
分別表示寄存器eax、ebx、ecx和edx
"S"和"D"
寄存器esi、edi
"I"
常數（0至31）
