公式是對價(jià)格、成交量、時(shí)間、周期等原始數據的比較判斷或者運算變化，說(shuō)通俗一點(diǎn)，就是我們告訴股票軟件做什么、怎么做的命令。
第一，公式可以提高我們的操作效率。
第二，公式可以幫助我們直觀(guān)地檢驗操作理念。
第三，使用公式構建自己的交易系統。
雖然現在到處可以找到各種各樣的公式，但卻很少剛好符合自己要求的，很多時(shí)候我們要對現成公式進(jìn)行修改或者重新編寫(xiě)。
即使你只使用現成的公式，也需要掌握一些公式編寫(xiě)知識。因為要使用好一條公式，必須了解公式的設計理念、前提條件、影響因素、變化規律、可靠性等等，而要了解這些，就得分析公式的算法。
本教程一共十節，詳細講解與公式編寫(xiě)相關(guān)的各種知識，絕大多數知識在飛狐、金狐、分析家、大智慧新一代、大智慧網(wǎng)絡(luò )版、通達信、同花順、操盤(pán)手、博易大師、文華等主流軟件上都是通用的，也就是說(shuō)，認真學(xué)完本教程，就可以在這些軟件上編寫(xiě)自己需要的常用公式。每一節的內容：
第一節，公式管理器——詳細講解公式管理器的每個(gè)功能，以及技術(shù)指標、條件選股、交易系統和五彩K線(xiàn)這四種不同類(lèi)型公式的特點(diǎn)。
第二節，添加現成公式——詳細講解如何添加現成公式，以及在添加公式時(shí)常見(jiàn)問(wèn)題的處理方法。
第三節，公式語(yǔ)句規則——詳細講解編寫(xiě)公式需要遵守的規則。
第四節，函數詳解——把函數按照實(shí)際功能進(jìn)行重新分類(lèi)，并結合實(shí)際應用對常用函數進(jìn)行詳細地講解。
第五節，公式轉換——詳細講解如何把技術(shù)指標變成選股公式、交易系統或者五彩K線(xiàn)等，并順帶講解如何給公式加上時(shí)間限制和如何解除公式的時(shí)間限制。
第六節，公式進(jìn)階——對如何進(jìn)行橫向統計、如何建立和使用擴展數據、如何建立和使用自定義數據、如何采集F10數據、如何建立板塊指數、如何編寫(xiě)分時(shí)圖公式等進(jìn)行詳細地演示。
第七節，公式測試——詳細講解如何對公式進(jìn)行測試、測試需要注意的事項以及如何正確看待測試的結果。
第八節，公式使用——詳細講解如何使用公式進(jìn)行選股和預警等。
第九節，公式解讀——詳細講解正確解讀公式的方法。
第十節，學(xué)習建議——推薦一些經(jīng)過(guò)實(shí)戰檢驗、個(gè)人認為真正能夠幫助大家實(shí)現穩定盈利的操作理念。
第01節 公式管理器
打開(kāi)公式管理器的方式：菜單欄中的功能——專(zhuān)家系統——公式管理器；工具欄中的公式管理器按鈕；鍵盤(pán)上的快捷鍵ctrl+f。
按照不同使用類(lèi)型分為技術(shù)指標、條件選股、交易系統和五彩K線(xiàn)這四大類(lèi)，一個(gè)大類(lèi)里面又分為很多小類(lèi)。全部——把某一類(lèi)型的公式完全展開(kāi)。系統——只顯示系統自帶的公式，前面有一個(gè)藍色小方塊。用戶(hù)——只顯示用戶(hù)添加的公式，前面有一個(gè)粉紅色小方塊。方塊前面有一個(gè)小鎖標志的是加密公式。
新建、修改（系統公式在關(guān)閉軟件后會(huì )自動(dòng)還原）、刪除、恢復、用戶(hù)配置、導出公式（密碼保護）、導入公式、臨時(shí)導入（關(guān)閉軟件后會(huì )自動(dòng)清除）、關(guān)閉。
公式名稱(chēng)（如果公式名稱(chēng)是漢字，快捷鍵是每個(gè)漢字的第一個(gè)拼音字母）、密碼保護、公式描述、公式類(lèi)型（自己編寫(xiě)的公式，最好選擇其它類(lèi)型）、畫(huà)線(xiàn)方法（副圖、主圖疊加、副圖（疊加K線(xiàn)）、疊加美國線(xiàn)、疊加收盤(pán)站線(xiàn)）、坐標線(xiàn)位置（自動(dòng)）、額外Y軸分界、引入指標公式、插入函數（把鼠標停留在函數上面，也可以看到它的說(shuō)明和用法）、測試公式、測試結果、參數欄、公式編輯區、動(dòng)態(tài)翻譯、參數精靈（Param #參數序號）、用法注釋。
技術(shù)指標調出方式：鍵盤(pán)上輸入技術(shù)指標名稱(chēng)；工具欄中的選擇指標按鈕；工具欄中的財經(jīng)資訊樹(shù)?？梢暂敵鼍€(xiàn)條、數字、圖形和文字，可以選股（需要指明條件）、不能預警、只有軟件自帶的一部分技術(shù)指標才能進(jìn)行系統測試。
條件選股公式在通達信中不能輸出顯示（要觀(guān)察它的信號，最好改成技術(shù)指標），只有一個(gè)輸出，可以選股、預警和系統測試。
交易系統公式調出方式：主圖上按右鍵——專(zhuān)家指示——交易系統指示；工具欄中的財經(jīng)資訊樹(shù)。成對輸出提示買(mǎi)賣(mài)的上下箭頭，可以選股（需要指明條件）、不能預警，可以系統測試。不想顯示交易系統指示：在箭頭上按右鍵——刪除交易系統指示。
五彩K線(xiàn)公式調出和刪除方法與交易系統一樣，通過(guò)不同顏色來(lái)區分滿(mǎn)足條件的K線(xiàn)和不滿(mǎn)足條件的K線(xiàn)，可以選股，不能預警和系統測試。
四種類(lèi)型的公式可以相互轉換，也可以組合使用。
第02節 添加現成公式
以文件形式顯示的是公式文件，可以看到函數和算法的是公式源碼。
Tni 通達信（新）Tnc通達信（老）
alg 飛狐、金狐
exp 大智慧網(wǎng)絡(luò )版
fnc 大智慧新一代、分析家
hxf 同花順
源碼：
INPUT:N(5,1,100),M(10,1,100);
N 1,100,5 M 1,100,10
N 5 M 10
{參數申明——中間（數字大小關(guān)系）數值為缺省值}
均線(xiàn)
MA1:MA(C,5);十日均線(xiàn)
MA2:MA(C,10),,COLORRED
{名稱(chēng)、語(yǔ)句說(shuō)明處理，逗號少多、缺少分號}
MA3：MA（C，20）；
{標點(diǎn)符號要英文樣式}
MA4:MA(MA(C,5),10;
{括號不匹配}
MA5:MA(C,30),COLORFF,LINEDASH;
{語(yǔ)句中有軟件不認識的函數}
MA5:=MA(MA7,5),CIRCLEDOT,COLORGREEN;
{公式不完整，中間語(yǔ)句不帶線(xiàn)型和顏色函數}
{主圖公式——畫(huà)線(xiàn)方法改成主圖疊加，條件選股公式——建立在條件選股類(lèi)別}
第03節 公式語(yǔ)句規則
MA1:MA(C,5),LINETHICK2,COLORRED;
{C:MA(C,5),LINETHICK2,COLORRED;}
{MA(C,5),LINETHICK2,COLORRED;}
指標線(xiàn)格式——指標線(xiàn)名稱(chēng):函數(數據,參數),線(xiàn)形,顏色;
指標線(xiàn)名稱(chēng)不能是c、o、h、l、v等系統保留字，同一公式中名稱(chēng)不能相同，也可沒(méi)有名稱(chēng)，如果沒(méi)有名稱(chēng)，冒號不用寫(xiě)，冒號、括號、逗號、分號等標點(diǎn)符號必須是英文的。
MA2: MA(MA1,5);
MA3:=MA(MA(C,5),10);{五日均線(xiàn)的十日簡(jiǎn)單移動(dòng)平均線(xiàn)}
空格和回車(chē)不影響公式計算，函數或者指標線(xiàn)名稱(chēng)不能被空格和回車(chē)分開(kāi)。冒號后面加上等號，把語(yǔ)句變成中間語(yǔ)句，中間語(yǔ)句不會(huì )輸出顯示，以免圖表凌亂、加快運算速度。括號從里到外運算、成對工作的，注釋部分用大括號括起來(lái)（飛狐可用//代替）。
Ma1:ma(c,5);
Ma2:ma(c,10);
Ma3:ma(c,20);
……
Man:ma(c,n);
Spj:=c;
Ma1:ma(spj,5);
Ma2:ma(spj,10);
Ma3:ma(spj,20);
……
Man:ma(spj,n);
引用其它公式指標線(xiàn)格式——"指標名稱(chēng).指標線(xiàn)名稱(chēng)"(參數表)
每個(gè)參數之間用逗號分開(kāi)，雙引號可要可不要；參數表可以不寫(xiě)。
K:"KDJ.K"(9,3,3);
{K:KDJ.K;}
跨周期引用格式——"指標名稱(chēng).指標線(xiàn)名稱(chēng)#周期"(參數表)
每個(gè)參數之間用逗號分開(kāi),雙引號和參數表可以不寫(xiě)。小周期可以引用大周期，大周期不能引用小周期。通達信跨周期引用有時(shí)會(huì )計算錯誤，最好在飛狐上使用。
日K:"KDJ.K";
周K:"KDJ.K#WEEK"(9,3,3);
三十分鐘K:KDJ.K#MIN30;
三十分鐘K:"KDJ.K";
日K:"KDJ.K#DAY";
周K:"KDJ.K#WEEK";
引用其它品種行情數據格式——"品種代碼代碼$行情函數"
雙引號一定要寫(xiě)。引用與當前股票相對應的大盤(pán)的數據，可用大盤(pán)行情函數。
萬(wàn)科A收盤(pán)價(jià):"000002$C";
綜藝股份收盤(pán)價(jià):"600770$C";
大盤(pán)收盤(pán)價(jià):INDEXC;
算術(shù)運算符：*/+-
比較運算符：=等于，!=不等于（飛狐<>），>大于,<小于，>=大于等于，<=小于等于
邏輯運算符：AND / &&與（并且），OR / ||或（或者）
運算順序從左到右、從上到下。
第04節 函數詳解
要有信心，不怕辛苦，要有方法。
主要函數——獲取數據、比較判斷、運算變化，輔助函數——修飾美化、形態(tài)描述。
K線(xiàn)數據，可以只寫(xiě)開(kāi)頭第一個(gè)字母。
開(kāi)盤(pán)價(jià):OPEN;{O}
收盤(pán)價(jià):CLOSE;{C}
最高價(jià):HIGH;{H}
最低價(jià):LOW;{L}
大盤(pán)K線(xiàn)數據，必須下載完整盤(pán)后數據。Drawkline——畫(huà)K線(xiàn)，數據順序——最高價(jià)、開(kāi)盤(pán)價(jià)、最低價(jià)、收盤(pán)價(jià)。
DRAWKLINE(INDEXH,INDEXO,INDEXL,INDEXC);
{H、O、L、C}
上漲家數和下跌家數，第一組只在大盤(pán)窗口才有數據，第二組哪個(gè)窗口都有數據。
漲家1:ADVANCE;
跌家1:DECLINE;
漲家2:INDEXADV;
跌家2:INDEXDEC;
在一定周期內某項數據的最大值——hhv，在一定周期內某項數據的最小值——llv。
HH:HHV(H,10);
LL:LLV(L,10);
MA1:MA(C,5);
HHMA:HHV(MA1,10);
LLMA:LLV(MA1,10);
創(chuàng )新高或者創(chuàng )新低。
創(chuàng )新高:H=HHV(H,60);
創(chuàng )新低:L=LLV(L,60);
當前位置取得以前位置數據——ref，取得指定日期數據——refdate，注意日期的格式。
以前數據:REF(C,1);
{以前數據:REF(H,2);}
指定日期數據:REFDATE(C,1090508);
{1998年5月25日——980525、2011年12月8日——1111208}
成交量——vol，可寫(xiě)成V，單位是手。成交金額——amount，單位是元。Indexv——大盤(pán)成交量， indexa——大盤(pán)成交金額。Buyvol——外盤(pán)， sellvol——內盤(pán)，只能取得與最后一根K線(xiàn)相對應的數據。
成交量:VOL;{V}
成交金額:=AMOUNT;
大盤(pán)成交量:=INDEXV;
大盤(pán)成交金額:=INDEXA;
外盤(pán):BUYVOL;
內盤(pán):SELLVOL;
漲幅、振幅、均價(jià)，成交量復權：工具——系統設置——設置1——勾選“分析圖成交量復權”——按確定——再按確定——退出K線(xiàn)圖——重新進(jìn)入K線(xiàn)圖。
漲幅:=(C-REF(C,1))/REF(C,1)*100;
振幅:=(H-L)/L*100;
均價(jià)1:(H+L+O+C)/4;
均價(jià)2:AMOUNT/(V*100);
即時(shí)行情函數只取得與最后一根K線(xiàn)相對應的數據。
振幅1:DYNAINFO(13)*100;
振幅2:(H-L)/L*100;
finance(7)的單位是股，根據流通盤(pán)變化而變化。capital的單位是手，只取得最新流通盤(pán)。
流通盤(pán)1:FINANCE(7);
流通盤(pán)2:CAPITAL;
換手率，finance(7)寫(xiě)的換手率更合理。
換手率1:V*100/FINANCE(7)*100;
換手率2:V/CAPITAL*100;
FINANCE(42)——上市日期，date——日期，date加19六個(gè)0，一號的日為0， year——年份，month——月份，day——日，weekday——星期。
上市日期:FINANCE(42);
日期1:DATE;
日期2:DATE+19000000;
年:YEAR;
月:MONTH;
日:DAY;
日期3:YEAR*10000+MONTH*100+DAY;
星期:WEEKDAY;
Time——時(shí)間，hour——小時(shí)，MINUTE——分鐘，只在日線(xiàn)以下周期有效。FROMOPEN——當前時(shí)刻距離開(kāi)盤(pán)分鐘數。
時(shí)間:TIME;
小時(shí):HOUR;
分鐘:MINUTE;
距開(kāi)盤(pán)分鐘數:FROMOPEN;
BARSCOUNT——某數據從第一個(gè)有效值到現在的周期數，TOTALBARSCOUNT——總周期數，下載完整盤(pán)后數據、不連接行情使用。CURRBARSCOUNT——當前K線(xiàn)到最后交易日周期數。
有效數據周期數:BARSCOUNT(C);
總周期數:TOTALBARSCOUNT;
到最后周期數:CURRBARSCOUNT;
Cross——是否發(fā)生交叉，兩條指標線(xiàn)不一定全是變化的曲線(xiàn)。Barslast——上一次條件成立到當前的周期數，BARSSINCE——第一次條件成立到當前的周期數，count——統計在一定周期內滿(mǎn)足條件的周期數。
K1:KDJ.K;
D1:KDJ.D;
金叉:CROSS(K1,D1)*10;
死叉:CROSS(D1,K1)*-10;
{K1上穿60:CROSS(K1,60);
K1下穿20:CROSS(20,K1);}
上次到現周期數:BARSLAST(金叉);
首次到現周期數:BARSSINCE(金叉),NODRAW;
統計{N周期內滿(mǎn)足條件}次數:COUNT(金叉=10,20);
Hhvbars——某數據在一定周期內的最大值到當前的周期數，llvbars——某數據在一定周期內的最小值到當前的周期數。
上一高點(diǎn){到現在}周期:HHVBARS(H,20);
上一低點(diǎn){到現在}周期:LLVBARS(L,20);
某數據是近多少周期內的最大值——TOPRANGE，某數據是近多少周期內的最小值——LOWRANGE。
多少周期的最大:TOPRANGE(H);
多少周期的最小:LOWRANGE(L);
BARSLASTCOUNT——統計連續滿(mǎn)足條件的周期數，sumbars——某數據向前累加到指定值到當前的周期數。
統計{連續滿(mǎn)足條件}周期數:BARSLASTCOUNT(C>REF(C,1));
加到指定值周期:SUMBARS(V,CAPITAL);
PERIOD——當前窗口的周期類(lèi)型。
窗口周期類(lèi)型:PERIOD;
在不同周期類(lèi)型使用不同參數。
參數:=IF(PERIOD=5,20,IF(PERIOD=6,10,0));
MA1:MA(C,參數);
最基本的比較判斷是用大于、小于、等于等等。某數據是否在某個(gè)范圍之內——RANGE，某數據是否在某個(gè)范圍——BETWEEN。
寬幅震蕩:(H-L)/L*100>12;
是否在某個(gè)范圍1:RANGE(C,8,10);{X>A AND A<B}
是否在某個(gè)范圍2:BETWEEN(C,10,13);{X>=A AND X<=B};
是否發(fā)生交叉——cross，LONGCROSS——是否維持一定周期后發(fā)生交叉。
上穿:CROSS(MA(C,5),MA(C,10));
{持續}一段時(shí)間后上穿:LONGCROSS(MA(C,5),MA(C,10),10)*2;
UPNDAY——某數據在一定周期內是否連漲，DOWNNDAY——某數據在一定周期內是否連跌，NDAY——是否在一定周期內前面的數據都大于后面的數據，ISLASTBAR——當前周期是否是最后一個(gè)周期。
連漲:UPNDAY(C,5);
連跌:DOWNNDAY(C,5);
連大:NDAY(C,O,5);
是否最后周期:ISLASTBAR;
EXIST——是否在一定周期內存在符合某種條件的情況，EVERY——是否在一定周期內一直存在符合條件的情況，LAST——是否在某一段周期內一直存在符合某種條件的情況，not——是否不符合條件。
存在:EXIST(C>REF(C,1)*1.099,10);
一直存在:EVERY(C>O,5);
持續存在:LAST(C>O,10,5);
并非:NOT(C>O);
If——是否符合條件，符合條件輸出前面的數據，不符合條件輸出后面的數據， max——哪個(gè)更大輸出哪個(gè)，min——哪個(gè)更小輸出哪個(gè)。
條件:=CROSS(MA(C,5),MA(C,10));
如果:IF(條件,5,-5);
較大者:MAX(C,O);
較小者:MIN(C,O);
FILTER——過(guò)濾連續出現的信號。
J大于80:"KDJ.J">80;
過(guò)濾:FILTER(J大于80,10)*2;
Abs——取得數據的絕對值，sum——求的數據在一定周期內的總和。
漲幅:(C-REF(C,1))/REF(C,1)*100;
零軸:0;
絕對值:ABS(漲幅);
求和:SUM(漲幅,5);
Ma——簡(jiǎn)單移動(dòng)平均值，ema——指數移動(dòng)平均值，sma——加權移動(dòng)平均值（前面參數大于后面參數），dma——動(dòng)態(tài)移動(dòng)平均值（參數小于1），后面三個(gè)函數降低本周期的權重、減少波動(dòng)性而使輸出變得相對平滑穩定，同時(shí)也降低了靈敏度。
簡(jiǎn)單移動(dòng)平均:MA(C,5);{(C0+C1+C2+…+C(N-1))/N}
指數移動(dòng)平均:EMA(C,5);{Y=2*X/(N+1)+(N-1)/(N+1)*Y',Y'上一周期Y}
加權移動(dòng)平均:SMA(C,5{N},1{M});{Y=(M*X+(N-M)*Y')/N, Y'上一周期Y,N必須大于M}
動(dòng)態(tài)移動(dòng)平均:DMA(C,0.5);{Y=N*X+(1-N)*Y',Y'上一周期Y,N必須小于1};
LINETHICK——粗細，color——顏色，stick——柱狀線(xiàn)，CROSSDOT——小交叉線(xiàn)，CIRCLEDOT——小圓圈線(xiàn)，POINTDOT——小圓點(diǎn)線(xiàn)。
MA1:MA(C,5);
MA2:MA(C,20),LINETHICK3,COLORRED;
均線(xiàn)差值1:(MA1-MA2)*1,STICK;
均線(xiàn)差值2:(MA1-MA2)*3,CROSSDOT;
均線(xiàn)差值3:(MA1-MA2)*6,CIRCLEDOT;
均線(xiàn)差值4:(MA1-MA2)*9,POINTDOT;
LINESTICK——指標線(xiàn)加柱狀線(xiàn)。
MA1:=MA(C,5);
MA2:=MA(C,10);
均線(xiàn)差值:MA1-MA2,LINESTICK;
COLORSTICK——彩色柱狀線(xiàn)。
MA1:=MA(C,5);
MA2:=MA(C,10);
均線(xiàn)差值:MA1-MA2,COLORSTICK;
VOLSTICK——成交量柱狀線(xiàn)。
MA1:=MA(C,5);
MA2:=MA(C,10);
均線(xiàn)差值:MA1-MA2,VOLSTICK;
DRAWTEXT——寫(xiě)文字（必須寫(xiě)在一對單引號內），DRAWICON——畫(huà)圖標。
MA1:MA(C,5);
MA2:MA(C,10);
金叉:=CROSS(MA1,MA2);
寫(xiě)文字:DRAWTEXT(金叉,MA1,'金叉');
畫(huà)圖標:DRAWICON(金叉,MA2,1);
STICKLINE——畫(huà)柱線(xiàn)，0實(shí)心柱，-1虛線(xiàn)空心柱，1實(shí)線(xiàn)空心柱。后面的輸出會(huì )遮擋住前面的輸出。
MA5:MA(C,5);
畫(huà)柱線(xiàn)1:STICKLINE(C>O,C,O,2,0);
畫(huà)柱線(xiàn)2:STICKLINE(C>O,H,L,0,0),COLORBLUE;
畫(huà)柱線(xiàn)3:STICKLINE(C<O,H,L,1,1);
畫(huà)柱線(xiàn)4:STICKLINE(C<O,C,O,3,-1);
MA10:MA(C,10),COLORGREEN;
DRAWLINE——繪制直線(xiàn)段，0不延長(cháng)，1向右延長(cháng)。PLOYLINE——繪制折線(xiàn)。
畫(huà)直線(xiàn):DRAWLINE(L=LLV(L,10),L,H=HHV(H,10),H,0);
畫(huà)折線(xiàn):PLOYLINE(H=HHV(H,30),H);
均線(xiàn)變色，DRAWNULL——返回無(wú)效值。nodraw——只輸出數值、不輸出線(xiàn)條，不影響公式坐標。LINETHICK0——只輸出數值、不輸出線(xiàn)條，在其它軟件中不影響公式坐標，在通達信中影響公式坐標。
MA1:MA(C,5);
MA2:MA(C,10);
變色:IF(MA1>REF(MA1,1),MA1,DRAWNULL),LINETHICK2,COLORRED;
成交量:V,NODRAW;
MA1:MA(C,5);
MA2:MA(C,10);
變色:IF(MA1>MA2,MA1,DRAWNULL),LINETHICK2,COLORRED;
成交量:V,LINETHICK0;
Winner——獲利盤(pán)，cost——成本分布情況。
獲利盤(pán):WINNER(C)*100;
成本分布:COST(80);
Zig——之字轉向，1最高價(jià)、2最低價(jià)、3收盤(pán)價(jià)。PEAK——波峰價(jià)格，1最高價(jià)、2最低價(jià)、3收盤(pán)價(jià)。TROUGH——波谷價(jià)格，1最高價(jià)、2最低價(jià)、3收盤(pán)價(jià)。
之字轉向:ZIG(3,10);
波峰:PEAK(3,10,1);
波谷:TROUGH(3,10,1);
波峰到現在的周期數——PEAKBARS，波谷到現在的周期數——TROUGHBARS。
波峰到現在周期:PEAKBARS(3,10,1);
波谷到現在周期:TROUGHBARS(3,10,1);
BACKSET——回設，馬后炮。
MA10:MA(C,10);
回設:=BACKSET(C/REF(C,1)>1.09,2);
A:=IF(REF(回設,1)=0 AND 回設=1,1,0);
DRAWICON(A,L*0.98,1);
跨周期引用的公式也具有未來(lái)性質(zhì)。
周J:"KDJ.J#WEEK";
周D:"KDJ.D#WEEK";
金叉:CROSS(周J,周D)*30;
還有一種作弊手法——將公式信號限制在有行情的時(shí)段發(fā)出。
另外一種作弊:O<REF(C,1) AND DATE=1080918;
建議暫時(shí)關(guān)閉本教程，把講義中這一節的內容挨個(gè)復制到你自己的軟件中，按照這一節開(kāi)始時(shí)所講的函數學(xué)習方法復習一遍。
要將自己的思路用公式去表達出來(lái)，首先是確定需要哪些數據，然后觀(guān)察這些數據之間的關(guān)系，再按語(yǔ)句規則的要求用函數去定義觀(guān)察到的關(guān)系。
{K線(xiàn)形態(tài)}
陰線(xiàn):C<O;
陽(yáng)線(xiàn):C>O;
上漲:C>REF(C,1);
下跌:C<REF(C,1);
平盤(pán):C=REF(C,1);
大陽(yáng)線(xiàn):C/REF(C,1)>1.05;
大陰線(xiàn):C/REF(C,1)<0.95;
高開(kāi):O>REF(C,1);
低開(kāi):O<REF(C,1);
高開(kāi)高走:O>REF(C,1) AND C>O;
高開(kāi)低走:O>REF(C,1) AND C<O;
低開(kāi)低走:O<REF(C,1) AND C<O;
低開(kāi)高走:O<REF(C,1) AND C>O;
上跳空:L>REF(H,1);
下跳空:H<REF(L,1);
長(cháng)上影:H/MAX(O,C)>1.03;
長(cháng)下影:MIN(O,C)/L>1.03;
十字星:MAX(O,C)/MIN(O,C)<1.02 AND H/MAX(O,C)>1.01 AND MIN(O,C)/L>1.01;
正T字:O=C AND C=H AND L<H;
倒T字:O=C AND C=L AND H>L;
一字漲停:O=C AND C=H AND L=H AND C>REF(C,1);
一字跌停:O=C AND C=L AND L=H AND C<REF(C,1);
橫盤(pán):HHV(H,20)/LLV(L,20)<1.15;
均線(xiàn)狀況——金叉和死叉。
MA1:MA(C,5);
MA2:MA(C,10);
金叉:CROSS(MA1,MA2);
死叉:CROSS(MA2,MA1);
均線(xiàn)上拐、下拐、將死未死。
MA1:MA(C,5);
MA2:MA(C,10);
上拐:=REF(MA1,1)<REF(MA1,2) AND MA1>REF(MA1,1);
下拐:=REF(MA1,1)>REF(MA1,2) AND MA1<REF(MA1,1);
將死未死:=COUNT(MA1>MA2,5)=5 AND 上拐;
DRAWICON(上拐,MA1*0.98,1);
DRAWICON(下拐,MA1*1.01,2);
DRAWICON(將死未死,MA1*0.96,11);
多頭排列、空頭排列。
MA1:MA(C,5);
MA2:MA(C,10);
MA3:MA(C,20);
多頭排列:=MA1>MA2 AND MA2>MA3;
空頭排列:=MA1<MA2 AND MA2<MA3;
STICKLINE(多頭排列,MA1,MA3,0,0),COLORRED;
STICKLINE(空頭排列,MA1,MA3,0,0),COLORGREEN;
均線(xiàn)粘合、粘合一段時(shí)間。
MA1:MA(C,5);
MA2:MA(C,10);
MA3:MA(C,20);
粘合:=MAX(MAX(MA1,MA2),MA3)/MIN(MIN(MA1,MA2),MA3)<1.02;
粘合一段時(shí)間:=COUNT(粘合,10)=10;
STICKLINE(粘合,MAX(MAX(MA1,MA2),MIN(MIN(MA1,MA2),MA3)),MA3,1,0),COLORRED;
DRAWICON(粘合一段時(shí)間,MA3*0.98,1);
三金叉。
DIF2:"MACD.DIF";
DEA2:"MACD.DEA";
單金叉:CROSS(DIF2,DEA2);
三金叉:(單金叉 AND COUNT(單金叉,10)>=3)*2;
成交量狀況——主要觀(guān)察成交量之間、成交量與均量線(xiàn)之間以及換手率之間的關(guān)系。放量、歷史天量。
放量1:V>REF(V,1)*2;
放量2:V>MA(V,60);
放量3:V*100/FINANCE(7)*100>8;
歷史天量:V=HHV(V,0);
連續放量。
連續放量1:COUNT(V>REF(V,1),5)=5;
連續放量2:(COUNT(V>MA(V,60),5)=5)*2;
連續放量3:(COUNT(V*100/FINANCE(7)*100>8,5)=5)*3;
縮量、歷史地量。
縮量1:V<REF(V,1)*0.5;
縮量2:V<MA(V,60);
縮量3:V*100/FINANCE(7)*100<1;
歷史地量:V=LLV(V,0);
連續縮量。
連續縮量1:COUNT(V<REF(V,1),5)=5;
連續縮量2:(COUNT(V<MA(V,60),5)=5)*2;
連續縮量3:(COUNT(V*100/FINANCE(7)*100<1,5)=5)*3;
籌碼低位密集。
籌碼密集:=(WINNER(C*1.1)-WINNER(C*0.9))*100>50;
相對低位:=(C-COST(0.01))/(COST(99.99)-COST(0.01))*100<10;
低位密集:籌碼密集 AND 相對低位;
第05節 公式轉換
技術(shù)指標轉換為條件選股公式：第一步，確定我們想要的信號；第二步，從下到上尋找信號的關(guān)聯(lián)語(yǔ)句；第三步，刪除無(wú)用語(yǔ)句；第四步，將信號以外的語(yǔ)句變成中間語(yǔ)句，并刪除修飾美化函數；第五步，將公式建立在條件選股類(lèi)別。
{改造前}
LC:=REF(C,1);
RSI1:SMA(MAX(C-LC,0),6,1)/SMA(ABS(C-LC),6,1)*100;
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:SMA(RSV,3,1);
D:SMA(K,3,1);
J:3*K-2*D,LINETHICK2;
MJ:=CROSS(J,D);
MC:=CROSS(D,J);
DRAWICON(MJ,J,1);
DRAWICON(MC,J,2);
{改造后}
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
CROSS(J,D);
技術(shù)指標轉換為交易系統公式：第一步，確定我們想要的信號；第二步，從下到上尋找信號的關(guān)聯(lián)語(yǔ)句；第三步，刪除無(wú)用語(yǔ)句；第四步，將信號以外的語(yǔ)句變成中間語(yǔ)句，并刪除修飾美化函數；第五步，將買(mǎi)進(jìn)信號取名為ENTERLONG，將賣(mài)出信號取名為EXITLONG；第六步，將公式建立在交易系統類(lèi)別。
{改造前}
{ ENTERLONG EXITLONG }
DIF:EMA(C,12)-EMA(C,26),LINETHICK2,COLORRED;
DIF下降:IF(DIF<=REF(DIF,1),DIF,DRAWNULL),LINETHICK2,COLORGREEN;
DEA:EMA(DIF,9),LINETHICK2,COLORBLUE;
MACD:(DIF-DEA)*2,COLORSTICK;
JCH:=CROSS(DIF,DEA);
SCH:=CROSS(DEA,DIF);
DRAWICON(JCH,DIF,1);
DRAWICON(SCH,DIF,2);
A:=MACD>REF(MACD,1) AND MACD<=0;
B:=MACD<=REF(MACD,1) AND MACD>0;
DRAWTEXT(A AND REF(A,1)=0,MACD*0.98,'☆'),COLORRED;
DRAWTEXT(B AND REF(B,1)=0,MACD*1.02,'☆'),COLORBLUE;
STICKLINE(MACD>REF(MACD,1) AND MACD>0,0,MACD,1,0),COLORRED;
STICKLINE(MACD<=REF(MACD,1) AND MACD>0,0,MACD,1,0),COLORYELLOW;
STICKLINE(MACD>REF(MACD,1) AND MACD<=0,0,MACD,1,0),COLORBLUE;
STICKLINE(MACD<=REF(MACD,1) AND MACD<=0,0,MACD,1,0),COLORGREEN;
{改造后}
DIF:=EMA(C,12)-EMA(C,26);
DEA:=EMA(DIF,9);
ENTERLONG:CROSS(DIF,DEA);
EXITLONG:CROSS(DEA,DIF);
技術(shù)指標轉換為五彩K線(xiàn)公式：第一步，確定我們想要的信號；第二步，從下到上尋找信號的關(guān)聯(lián)語(yǔ)句；第三步，刪除無(wú)用語(yǔ)句；第四步，將信號以外的語(yǔ)句變成中間語(yǔ)句，并刪除修飾美化函數；第五步，將公式建立在五彩K線(xiàn)類(lèi)別。
{改造前}
MA10:MA(C,10),linethick2,;
MA20:MA(C,20);
MA30:MA(C,30);
多頭排列:=MA10>MA20 AND MA20>MA30;
空頭排列:=MA10<MA20 AND MA20<MA30;
STICKLINE(多頭排列,MA10,MA30,0,0),COLORRED;
STICKLINE(空頭排列,MA10,MA30,0,0),COLORGREEN;
DRAWICON(REF(多頭排列,1)=0 AND 多頭排列,MA30,1);
DRAWICON(REF(多頭排列,1)=1 AND 多頭排列=0,MA10,2);
{改造后}
MA10:=MA(C,10);
MA20:=MA(C,20);
MA30:=MA(C,30);
多頭排列:MA10>MA20 AND MA20>MA30,COLORRED;
空頭排列:MA10<MA20 AND MA20<MA30,COLORYELLOW;
給公式加上時(shí)間限制——寫(xiě)一條日期判斷語(yǔ)句，從下往上尋找關(guān)鍵語(yǔ)句，在關(guān)鍵語(yǔ)句后面乘上日期判斷語(yǔ)句。
{改造前}
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:SMA(RSV,3,1);
D:SMA(K,3,1);
J:3*K-2*D;
{改造后1}
A:=IF(DATE>1090101,0,1);
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100*A;
K:SMA(RSV,3,1);
D:SMA(K,3,1);
J:3*K-2*D;
{改造后2}
A:=IF(DATE>1090101,0,1);
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100*A;
K:SMA(RSV,3,1)*A;
D:SMA(K,3,1)*A;
J:(3*K-2*D)*A;
解除公式時(shí)間限制——把日期改長(cháng)或直接刪除日期限制語(yǔ)句以及相關(guān)語(yǔ)句后面的乘上運算。
第06節 公式進(jìn)階
管理——橫向統計管理——新增——選中公式——設置范圍——按確定——再按確定——彈出詢(xún)問(wèn)我們【是否要立即計算數據】的對話(huà)框，如果你需要建立多個(gè)橫向統計數據，可以點(diǎn)否，等全部建立完再點(diǎn)擊全部刷新，如果你只需要建立一個(gè)橫向統計數據，一般點(diǎn)是——等軟件計算完，記住數據序號——關(guān)閉。
調用橫向統計數據——ESTDATA。
{KDJ金叉}
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
金叉:cross(k,d)
{KDJ金叉數量}
金叉數量:ESTDATA(N);
管理——擴展數據管理——雙擊其中一個(gè)擴展數據——選中公式——勾上生成橫向排名數據——設置范圍——按確定——再按確定——彈出詢(xún)問(wèn)我們【是否要立即計算數據】的對話(huà)框——我們點(diǎn)是——等軟件計算完，記住數據序號——關(guān)閉。
調用擴展數據——EXTDATA。
{J值排名}
排名:EXTDATA(N);
管理——擴展數據管理——雙擊其中一個(gè)擴展數據——選中公式——不要勾上生成橫向排名數據——設置范圍——按確定——再按確定——彈出詢(xún)問(wèn)我們【是否要立即計算數據】的對話(huà)框——選擇否——點(diǎn)擊全部刷新——等軟件計算完，記住數據序號——關(guān)閉。
EXTDATA——調用擴展數據，只有分筆數據完整準確，計算結果才準確。
{內外盤(pán)引用}
內盤(pán):DYNAINFO(22);
外盤(pán):DYNAINFO(23);
{內外盤(pán)}
內盤(pán):EXTDATA(2);
外盤(pán):EXTDATA(3);
管理——自定義數據管理——新建——名稱(chēng)——描述——屬性——確定——點(diǎn)擊保存、退出，不能點(diǎn)擊關(guān)閉。
F10資料下載地址：http://www.chcj.net/thread-1188029-1-1.html，上海巨靈F10和深圳巨靈F10。把上海F10解壓縮到——飛狐DATASHF10這個(gè)文件夾，把深圳F10解壓縮到——飛狐DATASZF10這個(gè)文件夾，然后重新啟動(dòng)飛狐。一定要選擇資料庫1。
管理——F10數據采集——彈出數據采集管理對話(huà)框——添加——進(jìn)行設置——確定。名稱(chēng)、描述、前導關(guān)鍵字（每個(gè)股票都相同、并且都有）、倍數、查找起始點(diǎn)和查找結束點(diǎn)（前導關(guān)鍵字前后不遠處每個(gè)股票都相同、并且都有）、數據存儲類(lèi)型（自定義數據）、測試、測試下一個(gè)、采集、保存。
調用自定義數據——selfdata。
{采集數據1}
每股收益:SELFDATA(1)/100;
使用數據采集函數采集F10數據，數字、標點(diǎn)符號和空格占一個(gè)字符，中文字占兩個(gè)字符。
{采集數據2}
a1:=F10FIND('2008-12-31│',1);
a2:=F10TEXT(a1+20,8);
八四每股凈資產(chǎn):STRTONUM(a2);
a3:=F10FIND('2009-03-31│',1);
a4:=F10TEXT(a3+20,8);
九一每股凈資產(chǎn):STRTONUM(a4);
{采集數據2}
a1:=F10FIND('◇機構持倉統計◇',1);
a2:=F10FIND('持倉總計',a1);
a3:=F10TEXT(a2+16,10);
機構持倉總計:STRTONUM(a3);
建立板塊指數：選擇版塊指數——空白區右鍵——新建板塊指數——彈出自定義指數對話(huà)框——進(jìn)行設置(指數成分股票——新增或者勾上版塊)——勾上實(shí)時(shí)刷新——確定——選中新建的版塊指數——右鍵——刷新板塊指數。
批量建立板塊指數：實(shí)盤(pán)獵莊——版塊分析——選中版塊分類(lèi)——全部版塊——右鍵——選擇批量創(chuàng )建版塊指數——進(jìn)行設置，勾上實(shí)時(shí)刷新——確定——關(guān)掉版塊分析——右鍵——刷新所有。
K線(xiàn)圖中的主圖公式，都可以疊加到分時(shí)圖。
把副圖公式疊加到分時(shí)圖主圖——對副圖公式進(jìn)行縮放，使指標線(xiàn)的變化范圍等于分時(shí)圖上面從最高價(jià)到最低價(jià)的范圍，然后移動(dòng)副圖公式，使副圖公式的指標線(xiàn)與分時(shí)圖的價(jià)格線(xiàn)對齊。
需要疊加其它公式，只需修改第二句、第三句和最后一句。一定要把主圖疊加勾上， YY1一定要引用變化較大的指標線(xiàn)。
{分時(shí)主圖疊加MACD}
IF DATATYPE>0 THEN EXIT;{只在分時(shí)圖運行此公式}
YY1:="MACD.DIFF";{引用變化大的指標線(xiàn)}
YY2:="MACD.DEA";{引用變化小的指標線(xiàn)}
ZQS:=DATACOUNT;{分時(shí)圖周期總數}
ZGJ:=DYNAINFO(5);{最高價(jià)}
ZDJ:=DYNAINFO(6);{最低價(jià)}
YY1ZDZ:=HHV(YY1,0);{YY1最大值}
ZHZDZ:=YY1ZDZ[ZQS];{YY1最大值最新數值}
YY1ZXZ:=LLV(YY1,0);{YY1最小值}
ZHZXZ:=YY1ZXZ[ZQS];{YY1最小值最新數值}
SFBL:=(ZGJ-ZDJ)/(ZHZDZ-ZHZXZ);{縮放比例}
PLJL:=ZGJ-ZHZDZ*SFBL;{偏移距離}
YY1*SFBL+PLJL,COLORRED;{縮放和移動(dòng)后的DIFF}
YY2*SFBL+PLJL,COLORBLUE;{縮放和移動(dòng)后的DEA}
0*SFBL+PLJL,POINTDOT;{縮放和移動(dòng)后的0軸}
{分時(shí)主圖疊加KDJ}
IF DATATYPE>0 THEN EXIT;{只在分時(shí)圖運行此公式}
YY1:="KDJ.K";{引用變化大的指標線(xiàn)}
YY2:="KDJ.D";{引用變化小的指標線(xiàn)}
ZQS:=DATACOUNT;{分時(shí)圖周期總數}
ZGJ:=DYNAINFO(5);{最高價(jià)}
ZDJ:=DYNAINFO(6);{最低價(jià)}
YY1ZDZ:=HHV(YY1,0);{YY1最大值}
ZHZDZ:=YY1ZDZ[ZQS];{YY1最大值最新數值}
YY1ZXZ:=LLV(YY1,0);{YY1最小值}
ZHZXZ:=YY1ZXZ[ZQS];{YY1最小值最新數值}
SFBL:=(ZGJ-ZDJ)/(ZHZDZ-ZHZXZ);{縮放比例}
PLJL:=ZGJ-ZHZDZ*SFBL;{偏移距離}
YY1*SFBL+PLJL,COLORRED;{縮放和移動(dòng)后的K}
YY2*SFBL+PLJL,COLORBLUE;{縮放和移動(dòng)后的D}
50*SFBL+PLJL,POINTDOT;{縮放和移動(dòng)后的50軸}
把副圖公式疊加到分時(shí)圖副圖——計算出副圖的最高位置和最低位置，把這個(gè)區域填充成黑色，重新畫(huà)六條坐標線(xiàn)，然后縮放副圖公式，使公式指標線(xiàn)的變化范圍等于副圖區域從最高位置到最低位置的范圍，最后移動(dòng)副圖公式，使公式的指標線(xiàn)與副圖的最高位置對齊。
需要疊加其它公式，只需修改YY這一句和最后三句。一定要把主圖疊加勾上， YY這一句一定要引用變化較大的指標線(xiàn)。
按小鍵盤(pán)上的乘號鍵，分時(shí)圖副圖變成了兩個(gè)，可以在兩個(gè)副圖上面疊加兩個(gè)不同的公式。
{分時(shí)副圖1疊加RSI}
ZSH:=DYNAINFO(3);{昨收}
ZQS:=DATACOUNT;{分時(shí)圖周期總數}
ZGJ:=DYNAINFO(5);{最高價(jià)}
ZDJ:=DYNAINFO(6);{最低價(jià)}
BZF:=MAX(ZGJ-ZSH,ZSH-ZDJ);{最大振幅的一半}
F1H:=ZSH-BZF*1.02;{分時(shí)副圖1最高位置}
F1L:=ZSH-2*BZF*1.005;{分時(shí)副圖1最低位置，同時(shí)也是分時(shí)副圖2最高位置}
FILLRGN(1,F1H,F1L),COLORBLACK;{清除原始副圖的指標線(xiàn)}
LDF:=(F1H-F1L)/6;{將分時(shí)副圖1六等分}
F1H+1*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+2*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+3*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+4*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+5*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
YY:="RSI.RSI1";{引用變化最大的指標線(xiàn)}
ZD:=HHV(YY,0);{引用的指標線(xiàn)的最大值}
ZX:=LLV(YY,0);{引用的指標線(xiàn)的最小值}
SFBL:=(F1H-F1L)/(ZD[ZQS]-ZX[ZQS]);{縮放比例}
PYJL:=(F1H+F1L-SFBL*(ZD[ZQS]+ZX[ZQS]))/2;{偏移距離}
YY*SFBL+PYJL,COLORRED;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的RSI1}
"RSI.RSI2"*SFBL+PYJL,COLORYELLOW;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的RSI2}
"RSI.RSI3"*SFBL+PYJL,COLORBLUE;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的RSI3}
{分時(shí)副圖1疊加KDJ}
ZSH:=DYNAINFO(3);{昨收}
ZQS:=DATACOUNT;{分時(shí)圖周期總數}
ZGJ:=DYNAINFO(5);{最高價(jià)}
ZDJ:=DYNAINFO(6);{最低價(jià)}
BZF:=MAX(ZGJ-ZSH,ZSH-ZDJ);{最大振幅的一半}
F1H:=ZSH-BZF*1.02;{分時(shí)副圖1最高位置}
F1L:=ZSH-2*BZF*1.005;{分時(shí)副圖1最低位置，同時(shí)也是分時(shí)副圖2最高位置}
FILLRGN(1,F1H,F1L),COLORBLACK;{清除原始副圖的指標線(xiàn)}
LDF:=(F1H-F1L)/6;{將分時(shí)副圖1六等分}
F1H+1*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+2*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+3*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+4*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+5*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
YY:="KDJ.J";{引用變化最大的指標線(xiàn)}
ZD:=HHV(YY,0);{引用的指標線(xiàn)的最大值}
ZX:=LLV(YY,0);{引用的指標線(xiàn)的最小值}
SFBL:=(F1H-F1L)/(ZD[ZQS]-ZX[ZQS]);{縮放比例}
PYJL:=(F1H+F1L-SFBL*(ZD[ZQS]+ZX[ZQS]))/2;{偏移距離}
YY*SFBL+PYJL,COLORRED;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的J}
"KDJ.K"*SFBL+PYJL,COLORYELLOW;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的K}
"KDJ.D"*SFBL+PYJL,COLORBLUE;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的D}
{分時(shí)副圖疊加兩個(gè)指標}
ZSH:=DYNAINFO(3);{昨收}
ZQS:=DATACOUNT;{分時(shí)圖周期總數}
ZGJ:=DYNAINFO(5);{最高價(jià)}
ZDJ:=DYNAINFO(6);{最低價(jià)}
BZF:=MAX(ZGJ-ZSH,ZSH-ZDJ);{最大振幅的一半}
F1H:=ZSH-BZF*1.02;{分時(shí)副圖1最高位置}
F1L:=ZSH-2*BZF*1.005;{分時(shí)副圖1最低位置，同時(shí)也是分時(shí)副圖2最高位置}
FILLRGN(1,F1H,F1L),COLORBLACK;{清除原始副圖的指標線(xiàn)}
LDF:=(F1H-F1L)/6;{將分時(shí)副圖1六等分}
F1H+1*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+2*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+3*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+4*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F1L+5*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
YY:="RSI.RSI1";{引用變化最大的指標線(xiàn)}
ZD:=HHV(YY,0);{引用的指標線(xiàn)的最大值}
ZX:=LLV(YY,0);{引用的指標線(xiàn)的最小值}
SFBL:=(F1H-F1L)/(ZD[ZQS]-ZX[ZQS]);{縮放比例}
PYJL:=(F1H+F1L-SFBL*(ZD[ZQS]+ZX[ZQS]))/2;{偏移距離}
YY*SFBL+PYJL,COLORRED;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的RSI1}
"RSI.RSI2"*SFBL+PYJL,COLORYELLOW;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的RSI2}
"RSI.RSI3"*SFBL+PYJL,COLORBLUE;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的RSI3}
F2H:=ZSH-2*BZF*1.01;{分時(shí)副圖2最高位置}
F2L:=ZSH-3*BZF*1.005;{分時(shí)副圖2最低位置}
FILLRGN(1,F2H,F2L),COLORBLACK;{清除原始副圖的指標線(xiàn)}
LDF:=(F2H-F2L)/6;{將分時(shí)副圖1六等分}
F2H+1*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F2L+2*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F2L+3*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F2L+4*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
F2L+5*LDF,POINTDOT,COLOR0000CC;{畫(huà)橫坐標線(xiàn)}
YY2:="KDJ.J";{引用變化最大的指標線(xiàn)}
ZD2:=HHV(YY2,0);{引用的指標線(xiàn)的最大值}
ZX2:=LLV(YY2,0);{引用的指標線(xiàn)的最小值}
SFBL2:=(F2H-F2L)/(ZD2[ZQS]-ZX2[ZQS]);{縮放比例}
PYJL2:=(F2H+F2L-SFBL2*(ZD2[ZQS]+ZX2[ZQS]))/2;{偏移距離}
YY2*SFBL2+PYJL2,COLORRED;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的J}
"KDJ.K"*SFBL2+PYJL2,COLORYELLOW;{在分時(shí)副圖1，顯示縮放和移動(dòng)后的K}
第07節 公式測試
程式化交易——條件選股——彈出條件選股對話(huà)框——選擇公式——成功率測試——彈出信號成功率測試對話(huà)框——設置測試時(shí)段、目標周期、目標利潤——先選多頭——測試，看共發(fā)出指示、平均成功率、利潤1總平均和利潤2總平均。
選中空頭再測試一次，這次主要看平均成功率。統計列表——哪些股票曾經(jīng)發(fā)出信號、信號成功率和相關(guān)利潤。雙擊有信號的股票，看信號在什么時(shí)候發(fā)出（紅箭頭成功信號，綠箭頭失敗信號）。分布圖，看信號分布與指數之間關(guān)系。
1996年12月26日之前沒(méi)有漲跌停限制。
對公式進(jìn)行必要的測試是可以的，但沒(méi)有必要太過(guò)在意測試的結果：
第一， 電腦計算的東西，不一定就是準確的。
第二， 國內股票軟件的測試功能都還很不完善。
第三， 測試結果只能代表過(guò)去，未來(lái)不一定如此。
第四， 無(wú)法做到跟測試結果一樣。
除了對公式進(jìn)行必要的測試，我們更應該認真分析公式源碼，搞清楚公式的前提條件、影響因素、變化規律，并判斷公式是否具有明確的市場(chǎng)含義、是否符合人性操作的邏輯、是否能夠及時(shí)反映多空力量的變化等等。要搞清楚這些東西，除了需要掌握公式編寫(xiě)知識，還得具有豐富的市場(chǎng)知識和市場(chǎng)實(shí)戰經(jīng)驗，這些都需要大家自己去慢慢積累。
第08節 公式使用
選股（條件選股公式）——功能——選股器——條件選股——彈出條件選股對話(huà)框——選擇公式——設置周期——加入條件（保存方案、引入方案）——設置范圍（歷史階段選股要有完整盤(pán)后數據）——選股入板塊或者執行選股。
選股（技術(shù)指標公式）——功能——選股器——綜合選股——彈出選股方案對話(huà)框——選擇公式——設置參數——條件設置——加入條件（保存方案、引入方案）——設置選股范圍和選股周期——選股入板塊或者執行選股。
預警（只有條件選股公式才能用來(lái)預警）——功能——預警系統——打開(kāi)條件預警開(kāi)關(guān)——功能——預警系統——條件預警設置——彈出條件預警設置對話(huà)框——添加股票——公式設置——添加公式——其它設置。
第09節 公式解讀
現在關(guān)于經(jīng)典公式的流行用法，基本上都是基于觀(guān)察公式表現的總結，要想真正用好經(jīng)典公式，單靠觀(guān)察總結肯定是不夠的，還得徹底分析清楚公式的源碼才行，我們現在來(lái)看如何解讀公式。
解讀公式步驟：第一步簡(jiǎn)化；第二步拆散；第三步分析（產(chǎn)生原因、變化規律以及相互關(guān)系）。
詳見(jiàn)視頻
RSI1:SMA(MAX(C-REF(C,1),0),14,1)/SMA(ABS(C-REF(C,1)),14,1);
A1:MAX(C-REF(C,1),0);
A2:SMA(A1,14,1);
B1:ABS(C-REF(C,1));
B2:SMA(B1,14,1);
RSI2:A2/B2;
詳見(jiàn)視頻
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:SMA(RSV,3,1);
D:SMA(K,3,1);
J:3*K-2*D;
HH:HHV(H,9);
LL:LLV(L,9);
SP:C;
J0:2*(K-D)+K;
聯(lián)系客服
