目錄
1、獲取默認網(wǎng)關(guān)
2、獲取IP地址
3、獲取MAC地址
4、獲取網(wǎng)絡(luò )地址
5、獲取子網(wǎng)掩碼
1、GetDG
函數 GetDG 返回默認網(wǎng)關(guān)。
| :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetDG dg
::
:: 作者：Ritchie Lawrence, 2003-09-22. 版本 1.0
::
:: 功能：獲取默認網(wǎng)關(guān)。如果失敗，將返回 0.0.0.0
:: 適用于 NT4/2000/XP/2003.
::
:: 參數：%1 該變量用于接收默認網(wǎng)關(guān)（引用調用）
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEEXTENSIONS & set "g=0.0.0.0" & set "j="
for /f "tokens=3" %%a in ('route print^|findstr 0.0.0.0.*0.0.0.0') do (
if not defined j for %%b in (%%a) do set "g=%%b" & set "j=1")
endlocal & set "%1=%g%" & goto :EOF
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: | |
參數
%1 該變量用于接收默認網(wǎng)關(guān)（引用調用）
返回值
見(jiàn)上述參數。
實(shí)例
@echo off & setlocal ENABLEEXTENSIONS
call :GetDG dg
echo/默認網(wǎng)關(guān)是：%dg%
goto :EOF
備注
如果電腦有多個(gè)網(wǎng)卡，返回的將是綁定在默認路由上的 IP 地址對應的網(wǎng)卡的默認網(wǎng)關(guān)。
參考
GetIP
2、GetIP
函數 GetIP 返回主網(wǎng)卡的 IP 地址。
| :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetIP ip
::
:: 作者：Ritchie Lawrence, 2003-09-22. 版本 1.0
::
:: 功能：主網(wǎng)卡的 IP 地址。如果失敗，將返回 0.0.0.0
:: 適用于 NT4/2000/XP/2003.
::
:: 參數：%1 該變量用于接收 IP 地址（引用調用）
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEEXTENSIONS & set "i=0.0.0.0" & set "j="
for /f "tokens=4" %%a in ('route print^|findstr 0.0.0.0.*0.0.0.0') do (
if not defined j for %%b in (%%a) do set "i=%%b" & set "j=1")
endlocal & set "%1=%i%" & goto :EOF
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: | |
參數
%1 該變量用于接收 IP 地址（引用調用）
返回值
見(jiàn)上述參數。
實(shí)例
@echo off & setlocal ENABLEEXTENSIONS
call :GetIP ip
echo/IP 地址是：%ip%
goto :EOF
備注
如果電腦有多個(gè)網(wǎng)卡，返回的將是綁定在默認路由上的 IP 地址對應的網(wǎng)卡的 IP 地址。
參考
GetMAC
3、GetMAC
函數 GetMAC 返回主網(wǎng)卡的 MAC 地址。
| :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetMAC mac
::
:: 作者：Ritchie Lawrence, 2003-09-24. 版本 1.0
::
:: 功能：主網(wǎng)卡的 MAC 地址，格式為XX-XX-XX-XX-XX-XX。
:: 如果失敗，將返回 00-00-00-00-00-00
:: 適用于 NT4/2000/XP/2003.
::
:: 參數：%1 該變量用于接收 MAC 地址（引用調用）
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEEXTENSIONS & set "m=00-00-00-00-00-00" & set "i=" & set "j="
set "n=0" & set "c=ipconfig/all" & set "f=findstr"
for /f "tokens=4" %%a in ('route print^|findstr 0.0.0.0.*0.0.0.0') do (
if not defined j for %%b in (%%a) do set "i=%%b" & set "j=1") & set "j="
if not defined i endlocal & set "%1=%m%" & goto :EOF
for /f "delims=:" %%a in ('%c%^|%f%/n IP.Address.*%i%') do set /a n=%%a-6
for /f "delims=" %%a in ('%c%^|more/e +%n%^|%f% Physical.Address') do (
if not defined j for %%b in (%%a) do set "m=%%b" & set "j=1")
endlocal & set "%1=%m%" & goto :EOF
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: | |
參數
%1 該變量用于接收 MAC 地址（引用調用）
返回值
見(jiàn)上述參數。
實(shí)例
@echo off & setlocal ENABLEEXTENSIONS
call :GetMAC mac
echo/MAC address is: %mac%
goto :EOF
備注
可以用變量替換來(lái)刪除結果中的橫線(xiàn)。比如：
:: 把橫線(xiàn)替換為空格
echo/MAC 地址是：%mac:-= %
:: 永久地刪除橫線(xiàn)
set "mac=%mac:-=%"
4、GetNA
函數 GetNA 返回主網(wǎng)卡的網(wǎng)絡(luò )地址。
| :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetNA na
::
:: 作者：Ritchie Lawrence, 2003-09-22. 版本 1.0
::
:: 功能：獲取主網(wǎng)卡的網(wǎng)絡(luò )地址。如果失敗，將返回 0.0.0.0
:: 適用于 NT4/2000/XP/2003.
::
:: 參數：%1 該變量用于接收網(wǎng)絡(luò )地址（引用調用）
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEEXTENSIONS & set "i=0.0.0.0" & set "n=0.0.0.0" & set "j="
for /f "tokens=4" %%a in ('route print^|findstr 0.0.0.0.*0.0.0.0') do (
if not defined j (for %%b in (%%a) do set "i=%%b" & set j=1)) & set "k="
for /f "skip=1 tokens=1,3-4" %%a in ('route print^|findstr/b /c:" "') do (
for %%e in (%%a) do set "x=%%e" & for %%f in (%%b) do set "y=%%f"
for %%g in (%%c) do set "z=%%g"
for /f "tokens=1-3" %%a in ('echo/%%x%% %%y%% %%z%%') do (
if not defined k if "%%c"=="%i%" if "%%b"=="%i%" set k=1 & set n=%%a))
endlocal & set "%1=%n%" & goto :EOF
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: | |
參數
%1 該變量用于接收網(wǎng)絡(luò )地址（引用調用）
返回值
見(jiàn)上述參數。
實(shí)例
@echo off & setlocal ENABLEEXTENSIONS
call :GetNA na
echo/網(wǎng)絡(luò )地址是：%na%
goto :EOF
備注
如果電腦有多個(gè)網(wǎng)卡，返回的將是綁定在默認路由上的 IP 地址對應的網(wǎng)卡的網(wǎng)絡(luò )地址。
注，第三、第四和第五個(gè) FOR 循環(huán)不使用空白符（制表符 TAB）是為了兼容 NT4.0。
5、GetSM
函數 GetSM 返回主網(wǎng)卡的子網(wǎng)掩碼。
| :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetSM sm
::
:: 作者：Ritchie Lawrence, 2003-09-22. 版本 1.0
::
:: 功能：獲取主網(wǎng)卡的子網(wǎng)掩碼。如果失敗，將返回 0.0.0.0
:: 適用于 NT4/2000/XP/2003.
::
:: 參數：%1 該變量用于接收子網(wǎng)掩碼（引用調用）
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEEXTENSIONS & set "i=0.0.0.0" & set "m=0.0.0.0" & set "j="
for /f "tokens=4" %%a in ('route print^|findstr 0.0.0.0.*0.0.0.0') do (
if not defined j (for %%b in (%%a) do set "i=%%b" & set j=1)) & set "k="
for /f "skip=1 tokens=2-4" %%a in ('route print^|findstr/b /c:" "') do (
for %%e in (%%a) do set "x=%%e" & for %%f in (%%b) do set "y=%%f"
for %%g in (%%c) do set "z=%%g"
for /f "tokens=1-3" %%a in ('echo/%%x%% %%y%% %%z%%') do (
if not defined k if "%%c"=="%i%" if "%%b"=="%i%" set k=1 & set m=%%a))
endlocal & set "%1=%m%" & goto :EOF
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: | |
參數
%1 該變量用于接收子網(wǎng)掩碼（引用調用）
返回值
見(jiàn)上述參數。
實(shí)例
@echo off & setlocal ENABLEEXTENSIONS
call :GetSM sm
echo/子網(wǎng)掩碼是：%sm%
goto :EOF
備注
如果電腦有多個(gè)網(wǎng)卡，返回的將是綁定在默認路由上的 IP 地址對應的網(wǎng)卡的網(wǎng)絡(luò )地址。
注，第三、第四和第五個(gè) FOR 循環(huán)不使用空白符（制表符 TAB）是為了兼容 NT4.0。
