MSDN 上的一個(gè)示例，你研究一下吧。是針對你這個(gè)問(wèn)題。
Children 屬性示例
這個(gè)例子在 TreeView 控件中放置幾個(gè) Node 對象。這組代碼檢查 Node 是否有子節點(diǎn)。如果有，則顯示子節點(diǎn)的文本。為試用此例，在窗體上安放一個(gè) TreeView 控件，并在窗體的聲明部分中粘貼下面的代碼。運行此例，單擊 Node 對象以選擇它，然后單擊該窗體來(lái)察看 Node 對象的子節點(diǎn)的文本。
Option Explicit
Private Sub Form_Click()
Dim strC As String
Dim N As Integer
If TreeView1.SelectedItem.Children > 0 Then '有子節點(diǎn)。
'獲取第一個(gè)子節點(diǎn)的文本，并將 N 設置為它的索引值。
strC = TreeView1.SelectedItem.Child.Text & vbLF
N = TreeView1.SelectedItem.Child.Index
'若 N 不是子節點(diǎn)的最后相鄰節點(diǎn)的索引，
'則獲取下一個(gè)相鄰節點(diǎn)的文本。
While N <> TreeView1.SelectedItem.Child.LastSibling.Index
strC = strC & TreeView1.Nodes(N).Next.Text & vbLF
'重置 N 為下一個(gè)相鄰節點(diǎn)的索引。
N = TreeView1.Nodes(N).Next.Index
Wend
'顯示結果。
MsgBox "Children of " & TreeView1.SelectedItem.Text & _
" are: " & vbLF & strC
Else '沒(méi)有子節點(diǎn)。
MsgBox TreeView1.SelectedItem.Text & " has no children"
End If
End Sub
Private Sub Form_Load()
TreeView1.BorderStyle = 1 '確保邊界是可視的。
Dim nodX As Node
Set nodX = TreeView1.Nodes.Add(,,"d","Dates")
Set nodX = TreeView1.Nodes.Add("d",tvwChild,"d89","1989")
Set nodX = TreeView1.Nodes.Add("d",tvwChild,"d90","1990")
'創(chuàng )建 1989 節點(diǎn)的子節點(diǎn)。
Set nodX = TreeView1.Nodes.Add("d89",tvwChild, ,"John")
Set nodX = TreeView1.Nodes.Add("d89",tvwChild, ,"Brent")
Set nodX = TreeView1.Nodes.Add("d89",tvwChild, ,"Eric")
Set nodX = TreeView1.Nodes.Add("d89",tvwChild, ,"Ian")
nodX.EnsureVisible '顯示所有節點(diǎn)。
'創(chuàng )建 1990 節點(diǎn)的子節點(diǎn)。
Set nodX = TreeView1.Nodes.Add("d90",tvwChild, ,"Randy")
Set nodX = TreeView1.Nodes.Add("d90",tvwChild, ,"Ron")
nodX.EnsureVisible '顯示所有節點(diǎn)。
End Sub
本站僅提供存儲服務(wù)，所有內容均由用戶(hù)發(fā)布，如發(fā)現有害或侵權內容，請
點(diǎn)擊舉報。
