（特別感謝匯編高手 dREAMtHEATER 對我的代碼作出了相當好的優(yōu)化！請參觀(guān)他的主頁(yè)）上一節我們介紹了花指令，不過(guò)花指令畢竟是一種很簡(jiǎn)單的東西，基本上入了門(mén)的Cracker都可以對付得了。所以，我們很有必要給自己的軟件加上更好的保護。CRC校驗就是其中的一種不錯的方法。
CRC是什么東西呢？其實(shí)我們大家都不應該會(huì )對它陌生，回憶一下？你用過(guò)RAR和ZIP等壓縮軟件嗎？它們是不是常常會(huì )給你一個(gè)惱人的“CRC校驗錯誤”信息呢？我想你應該明白了吧，CRC就是塊數據的計算值，它的全稱(chēng)是“Cyclic Redundancy Check”，中文名是“循環(huán)冗余碼”，“CRC校驗”就是“循環(huán)冗余校驗”。（哇，真拗口，希望大家不要當我是唐僧，呵呵。^_^）
CRC有什么用呢？它的應用范圍很廣泛，最常見(jiàn)的就是在網(wǎng)絡(luò )傳輸中進(jìn)行信息的校對。其實(shí)我們大可以把它應用到軟件保護中去，因為它的計算是非常非常非常嚴格的。嚴格到什么程度呢？你的程序只要被改動(dòng)了一個(gè)字節（甚至只是大小寫(xiě)的改動(dòng)），它的值就會(huì )跟原來(lái)的不同。Hoho，是不是很厲害呢？所以只要給你的“原”程序計算好CRC值，儲存在某個(gè)地方，然后在程序中隨機地再對文件進(jìn)行CRC校驗，接著(zhù)跟第一次生成并保存好的CRC值進(jìn)行比較，如果相等的話(huà)就說(shuō)明你的程序沒(méi)有被修改/破解過(guò)，如果不等的話(huà)，那么很可能你的程序遭到了病毒的感染，或者被Cracker用16進(jìn)制工具暴力破解過(guò)了。
廢話(huà)說(shuō)完了，我們先來(lái)看看CRC的原理。
（由于CRC實(shí)現起來(lái)有一定的難度，所以具體怎樣用它來(lái)保護文件，留待下一節再講。）
首先看兩個(gè)式子：
式一：9 / 3 = 3 （余數 = 0）
式二：(9 + 2 ) / 3 = 3 （余數 = 2）
在小學(xué)里我們就知道，除法運算就是將被減數重復地減去除數X次，然后留下余數。
所以上面的兩個(gè)式子可以用二進(jìn)制計算為：（什么？你不會(huì )二進(jìn)制計算？我倒～～～）
式一：
1001 --> 9
0011 - --> 3
---------
0110 --> 6
0011 - --> 3
---------
0011 --> 3
0011 - --> 3
---------
0000 --> 0，余數
一共減了3次，所以商是3，而最后一次減出來(lái)的結果是0，所以余數為0
式二：
1011 --> 11
0011 - --> 3
---------
1000 --> 8
0011 - --> 3
---------
0101 --> 5
0011 - --> 3
---------
0010 --> 2,余數
一共減了3次，所以商是3，而最后一次減出來(lái)的結果是2，所以余數為2
看明白了吧？很好，let’s go on!
二進(jìn)制減法運算的規則是，如果遇到0-1的情況，那么要從高位借1，就變成了(10+0)-1=1
CRC運算有什么不同呢？讓我們看下面的例子：
這次用式子30 / 9，不過(guò)請讀者注意最后的余數：
11110 --> 30
1001 - --> 9
---------
1100 --> 12 （很奇怪吧？為什么不是21呢？）
1001 - --> 9
--------
101 --> 3，余數 --> the CRC!
這個(gè)式子的計算過(guò)程是不是很奇怪呢？它不是直接減的，而是用XOR的方式來(lái)運算（程序員應該都很熟悉XOR吧），最后得到一個(gè)余數。
對啦，這個(gè)就是CRC的運算方法，明白了嗎？CRC的本質(zhì)是進(jìn)行XOR運算，運算的過(guò)程我們不用管它，因為運算過(guò)程對最后的結果沒(méi)有意義；我們真正感興趣的只是最終得到的余數，這個(gè)余數就是CRC值。
進(jìn)行一個(gè)CRC運算我們需要選擇一個(gè)除數，這個(gè)除數我們叫它為“poly”，寬度W就是最高位的位置，所以我剛才舉的例子中的除數9，這個(gè)poly 1001的W是3，而不是4，注意最高位總是1。（別問(wèn)為什么，這個(gè)是規定）
如果我們想計算一個(gè)位串的CRC碼，我們想確定每一個(gè)位都被處理過(guò)，因此，我們要在目標位串后面加上W個(gè)0位?，F在讓我們根據CRC的規范來(lái)改寫(xiě)一下上面的例子：
Poly = 1001，寬度W = 3
位串Bitstring = 11110
Bitstring + W zeroes = 11110 + 000 = 11110000
11110000
1001|||| -
-------------
1100|||
1001||| -
------------
1010||
1001|| -
-----------
0110|
0000| -
----------
1100
1001 -
---------
101 --> 3，余數 --> the CRC!
還有兩點(diǎn)重要聲明如下：
1、只有當Bitstring的最高位為1，我們才將它與poly進(jìn)行XOR運算，否則我們只是將Bitstring左移一位。
2、XOR運算的結果就是被操作位串Bitstring與poly的低W位進(jìn)行XOR運算，因為最高位總為0。
呵呵，是不是有點(diǎn)頭暈腦脹的感覺(jué)了？看不懂的話(huà)，再從頭看一遍，其實(shí)是很好理解的。（就是一個(gè)XOR運算嘛?。?br>
好啦，原理介紹到這里，下面我講講具體怎么編程。
由于速度的關(guān)系，CRC的實(shí)現主要是通過(guò)查表法，對于CRC-16和CRC-32，各自有一個(gè)現成的表，大家可以直接引入到程序中使用。（由于這兩個(gè)表太長(cháng)，在這里不列出來(lái)了，請讀者自行在網(wǎng)絡(luò )上查找，很容易找到的。）
如果我們沒(méi)有這個(gè)表怎么辦呢？或者你跟我一樣，懶得自己輸入？不用急，我們可以“自己動(dòng)手，豐衣足食”。
你可能會(huì )說(shuō)，自己編程來(lái)生成這個(gè)表，會(huì )不會(huì )太慢了？其實(shí)大可不必擔心，因為我們是在匯編代碼的級別進(jìn)行運算的，而這個(gè)表只有區區256個(gè)雙字，根本影響不了速度。
這個(gè)表的C語(yǔ)言描述如下：
for (i = 0; i < 256; i++)
{
crc = i;
for (j = 0; j < 8; j++)
{
if (crc & 1)
crc = (crc >> 1) ^ 0xEDB88320;
else
crc >>= 1;
}
crc32tbl[i] = crc;
}
生成表之后，就可以進(jìn)行運算了。
我們的算法如下：
1、將寄存器向右邊移動(dòng)一個(gè)字節。
2、將剛移出的那個(gè)字節與我們的字符串中的新字節進(jìn)行XOR運算，得出一個(gè)指向值表table[0..255]的索引。
3、將索引所指的表值與寄存器做XOR運算。
4、如果數據沒(méi)有全部處理完，則跳到步驟1。
這個(gè)算法的C語(yǔ)言描述如下：
temp = (oldcrc ^ abyte) & 0x000000FF;
crc = (( oldcrc >> 8) & 0x00FFFFFF) ^ crc32tbl[temp];
return crc;
好啦，所有的東東都說(shuō)完啦，最后獻上一個(gè)完整的Win32Asm例子，請讀者仔細研究吧！
（匯編方面的CRC-32資料極少啊，我個(gè)人認為下面給出的是很寶貴的資料。）
;***********************************************************************************************
;程序名稱(chēng)：演示CRC32原理
;作者：羅聰
;日期：2002-8-24
;出處：http://laoluoc.yeah.net（老羅的繽紛天地）
;注意事項：如欲轉載，請保持本程序的完整，并注明：轉載自“老羅的繽紛天地”（http://laoluoc.yeah.net）
;
;特別感謝Win32ASM高手—— dREAMtHEATER 為我的代碼作了相當好的優(yōu)化！
;請各位前去 http://NoteXPad.yeah.net 下載他的小巧的“cool 記事本”—— NoteXPad 來(lái)試用?。?00% Win32ASM 編寫(xiě)）
;
;***********************************************************************************************
.386
.model flat, stdcall
option casemap:none
include windows.inc
include kernel32.inc
include user32.inc
includelib kernel32.lib
includelib user32.lib
WndProc proto :DWORD, :DWORD, :DWORD, :DWORD
init_crc32table proto
arraycrc32 proto
.const
IDC_BUTTON_OPEN equ 3000
IDC_EDIT_INPUT equ 3001
.data
szDlgName db "lc_dialog", 0
szTitle db "CRC demo by LC", 0
szTemplate db "字符串 ""%s"" 的 CRC32 值是：%X", 0
crc32tbl dd 256 dup(0) ;CRC-32 table
szBuffer db 255 dup(0)
.data?
szText db 300 dup(?)
.code
main:
invoke GetModuleHandle, NULL
invoke DialogBoxParam, eax, offset szDlgName, 0, WndProc, 0
invoke ExitProcess, eax
WndProc proc uses ebx hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
.if uMsg == WM_CLOSE
invoke EndDialog, hWnd, 0
.elseif uMsg == WM_COMMAND
mov eax,wParam
mov edx,eax
shr edx,16
movzx eax, ax
.if edx == BN_CLICKED
.IF eax == IDCANCEL
invoke EndDialog, hWnd, NULL
.ELSEIF eax == IDC_BUTTON_OPEN || eax == IDOK
;******************************************
;關(guān)鍵代碼開(kāi)始：（當當當當……）
;******************************************
;取得用戶(hù)輸入的字符串：
invoke GetDlgItemText, hWnd, IDC_EDIT_INPUT, addr szBuffer, 255
;初始化crc32table：
invoke init_crc32table
;下面賦值給寄存器ebx，以便進(jìn)行crc32轉換：
;EBX是待轉換的字符串的首地址：
lea ebx, szBuffer
;進(jìn)行crc32轉換：
invoke arraycrc32
;格式化輸出：
invoke wsprintf, addr szText, addr szTemplate, addr szBuffer, eax
;好啦，讓我們顯示結果：
invoke MessageBox, hWnd, addr szText, addr szTitle, MB_OK
.ENDIF
.endif
.ELSE
mov eax,FALSE
ret
.ENDIF
mov eax,TRUE
ret
WndProc endp
;**********************************************************
;函數功能：生成CRC-32表
;**********************************************************
init_crc32table proc
;如果用C語(yǔ)言來(lái)表示，應該如下：
;
; for (i = 0; i < 256; i++)
; {
; crc = i;
; for (j = 0; j < 8; j++)
; {
; if (crc & 1)
; crc = (crc >> 1) ^ 0xEDB88320;
; else
; crc >>= 1;
; }
; crc32tbl[i] = crc;
; }
;
;呵呵，讓我們把上面的語(yǔ)句改成assembly的：
mov ecx, 256 ; repeat for every DWORD in table
mov edx, 0EDB88320h
$BigLoop:
lea eax, [ecx-1]
push ecx
mov ecx, 8
$SmallLoop:
shr eax, 1
jnc @F
xor eax, edx
@@:
dec ecx
jne $SmallLoop
pop ecx
mov [crc32tbl+ecx*4-4], eax
dec ecx
jne $BigLoop
ret
init_crc32table endp
;**************************************************************
;函數功能：計算CRC-32
;**************************************************************
arraycrc32 proc
;計算 CRC-32 ，我采用的是把整個(gè)字符串當作一個(gè)數組，然后把這個(gè)數組的首地址賦值給 EBX，把數組的長(cháng)度賦值給 ECX，然后循環(huán)計算，返回值（計算出來(lái)的 CRC-32 值）儲存在 EAX 中：
;
; 參數：
; EBX = address of first byte
; 返回值：
; EAX = CRC-32 of the entire array
; EBX = ?
; ECX = 0
; EDX = ?
mov eax, -1 ; 先初始化eax
or ebx, ebx
jz $Done ; 避免出現空指針
@@:
mov dl, [ebx]
or dl, dl
je $Done ;判斷是否對字符串掃描完畢
;這里我用查表法來(lái)計算 CRC-32 ，因此非?？焖伲?/font>
;因為這是assembly代碼，所以不需要給這個(gè)過(guò)程傳遞參數，只需要把oldcrc賦值給EAX，以及把byte賦值給DL：
;
; 在C語(yǔ)言中的形式：
;
; temp = (oldcrc ^ abyte) & 0x000000FF;
; crc = (( oldcrc >> 8) & 0x00FFFFFF) ^ crc32tbl[temp];
;
; 參數：
; EAX = old CRC-32
; DL = a byte
; 返回值：
; EAX = new CRC-32
; EDX = ?
xor dl, al
movzx edx, dl
shr eax, 8
xor eax, [crc32tbl+edx*4]
inc ebx
jmp @B
$Done:
not eax
ret
arraycrc32 endp
end main
;*************************** over ***************************************
;by LC
下面是它的.rc文件：
#include "resource.h"
#define IDC_BUTTON_OPEN 3000
#define IDC_EDIT_INPUT 3001
#define IDC_STATIC -1
LC_DIALOG DIALOGEX 10, 10, 195, 60
STYLE DS_SETFONT | DS_CENTER | WS_MINIMIZEBOX | WS_VISIBLE | WS_CAPTION |
WS_SYSMENU
CAPTION "lc’s assembly framework"
FONT 9, "宋體", 0, 0, 0x0
BEGIN
LTEXT "請輸入一個(gè)字符串（區分大小寫(xiě)）：",IDC_STATIC,11,7,130,10
EDITTEXT IDC_EDIT_INPUT,11,20,173,12,ES_AUTOHSCROLL
DEFPUSHBUTTON "Ca&lc",IDC_BUTTON_OPEN,71,39,52,15
END
如果你能夠完全理解本節的內容，那么請留意我的下一講，我將具體介紹如何運用CRC-32對你的文件進(jìn)行保護。（呵呵，好戲在后頭……）
