如今OCX控件在編程中已占領(lǐng)了很重要的地位,我們可以利用OCX控件完成一些相當復雜的編程操作.同時(shí)OCX 控件還有利于主程序的簡(jiǎn)單化、功能的重用、隱常程序實(shí)現細節、便于升級、傳播方便等優(yōu)點(diǎn)?，F在我們可以利用VB 5.0方便的制作出自己的OCX控件供我們在編程中使用同時(shí)還可以把它送給你周?chē)矚g編程的朋友!
下面列出制作OCX控件的步驟：
一：新建OCX 打開(kāi)VB 5.0選擇新建工程在對話(huà)框中選擇ActiveX 控件(如圖一(map1.gif))打開(kāi)后會(huì )見(jiàn)一空的文檔這就是 OCX控件的初始界面。想看一看空OCX控件的效果嗎?選擇“添加工程”選中標準EXE，這時(shí)你就可以像調用其它控件一樣在左邊的工具欄里選擇剛才新建的OCX控件圖標放在標準的EXE文檔中看一看有什么效果!(什么也沒(méi)有!) 自然因為剛才的OCX文檔是空的嘛(廢話(huà)太多，數個(gè)痰盂向我飛來(lái))!
二：創(chuàng )建界面
一般我們用VB創(chuàng )建OCX控件都是在我們的控件里添加其它的控件來(lái)組合成一個(gè)完整的控件（也可以讓它只完成某種算法）比如：你可以在上面添加一按鈕、編輯框這時(shí)你再用第一部的方法看一看效果，是不是控件上多了一個(gè)按鈕和一個(gè)編輯框。
三：OCX屬性
一個(gè)OCX控件有許多的屬性，比如控件背景是否透明（BackStyle），控件是否可以獲得焦點(diǎn) (CanGetFocus)等。這些屬性都可以在控件的“屬性框”中找到。
四：添加事件
一個(gè)控件有很多事件如：Click、MouseDown、MouseUp、MouseMove等。要觸發(fā)這些事件都需要你加入代碼。在控件的聲明處加入Public Event Click()就表明該控件有一“Click”事件。自己編寫(xiě)的控件有什么事件就在聲明處加幾條事件。關(guān)于觸發(fā)事件是使用“RaiseEvent”語(yǔ)句來(lái)完成的如：RaiseEvent 事件名（參數）。 五：用戶(hù)屬性
一個(gè)控件應有許多屬性供用戶(hù)設置如：控件的背景色、控件要顯示的圖形等。它們通常用Property Get和 Property Let兩條語(yǔ)句來(lái)完成。前者表示給用戶(hù)顯示一個(gè)屬性的值，后者表示用戶(hù)設置一個(gè)屬性的值。 六：保存屬性和讀取屬性
當屬性被用戶(hù)更改后需要將該屬性值保存，以便控件運行時(shí)讀取更改后的屬性值。它們分別用 ReadProperty和WriteProperty兩種方法來(lái)完成。前者表示讀取一個(gè)屬性值，后者表示寫(xiě)入一個(gè)屬性值。
好了一個(gè)簡(jiǎn)單的OCX控件制作方法大概就需要以上幾步就可完成。下面本人將編寫(xiě)一個(gè)簡(jiǎn)單的OCX控件供大家參考。此控件的功能是在控件中顯示一個(gè)圓，當鼠標移到控件上的時(shí)候控件上的圓便會(huì )在鼠標不離開(kāi)控件的前提下跟隨鼠標移動(dòng)。
新建一OCX控件，將控件的BorderStyle屬性改為1，再加入一SHAPE控件將其形狀改為Circle(如圖二(map2.gif)) 添加以下代碼：
Public Event Click() '定義該控件要產(chǎn)生的事件
Dim CircleX As Integer, CircleY As Integer
Private Sub UserControl_Click()
RaiseEvent Click '觸發(fā)Click事件
End Sub
Private Sub UserControl_Initialize()
CircleX = Shape1.Width / 2
CircleY = Shape1.Height / 2
End Sub
Private Sub UserControl_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
Shape1.BackColor = RGB(0, 0, 255)
End Sub
Private Sub UserControl_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim MoveX As Integer, MoveY As Integer
MoveX = X - Shape1.Width / 2
MoveY = Y - Shape1.Height / 2
If (MoveX < 0) Or (MoveX + Shape1.Width > UserControl.ScaleWidth) Or _
(MoveY < 0) Or (MoveY + Shape1.Height > UserControl.ScaleHeight) Then Exit Sub
Shape1.Move MoveX, MoveY
End Sub
Private Sub UserControl_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
Shape1.BackColor = RGB(255, 0, 0)
End Sub
Property Get PosX() As Integer '取得CircleX的值顯示給用戶(hù)
PosX = CircleX
End Property
Property Let PosX(ByVal New_X As Integer) '把用戶(hù)寫(xiě)入的值設置到OCX控件內部
If (New_X < Shape1.Width / 2) Or _
(New_X > UserControl.ScaleWidth - Shape1.Width / 2) Then
MsgBox ("圓的X值超出界限了")
Else
CircleX = New_X
Call UserControl_Resize
End If
End Property
Property Get PosY() As Integer
PosY = CircleY
End Property
Property Let PosY(ByVal New_Y As Integer)
If (New_Y < Shape1.Height / 2) Or _
(New_Y > UserControl.ScaleHeight - Shape1.Height / 2) Then
MsgBox ("圓的Y值超出界限了")
Else
CircleY = New_Y
Call UserControl_Resize
End If
End Property
Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
CircleX = PropBag.ReadProperty("CircleX", Shape1.Width / 2) '將用戶(hù)設置的值讀出來(lái)
CircleY = PropBag.ReadProperty("CircleY", Shape1.Height / 2) '同上
Call UserControl_Resize
End Sub
Private Sub UserControl_Resize()
Shape1.Move CircleX, CircleY
End Sub
Private Sub UserControl_WriteProperties(PropBag As PropertyBag)
Call PropBag.WriteProperty("CircleX", CircleX, Shape1.Width / 2) '將用戶(hù)設置的值保存
Call PropBag.WriteProperty("CircleY", CircleY, Shape1.Height / 2) '同上
End Sub
